Convert to distutils-r1.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 60 insertions, 1 deletions

diff --git a/app-editors/editra/ChangeLog b/app-editors/editra/ChangeLog
index 53be3286607e..14196afdd1a6 100644
--- a/app-editors/editra/ChangeLog
+++ b/app-editors/editra/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/editra
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/editra/ChangeLog,v 1.37 2014/08/10 17:41:03 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/editra/ChangeLog,v 1.38 2014/12/26 22:43:47 mgorny Exp $
+
+*editra-0.7.20-r1 (26 Dec 2014)
+
+  26 Dec 2014; Michał Górny <mgorny@gentoo.org> +editra-0.7.20-r1.ebuild:
+  Convert to distutils-r1.
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org> editra-0.7.12.ebuild,
   editra-0.7.20.ebuild:
diff --git a/app-editors/editra/editra-0.7.20-r1.ebuild b/app-editors/editra/editra-0.7.20-r1.ebuild
new file mode 100644
index 000000000000..eb6a1d2980e8
--- /dev/null
+++ b/app-editors/editra/editra-0.7.20-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/editra/editra-0.7.20-r1.ebuild,v 1.1 2014/12/26 22:43:47 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils fdo-mime
+
+MY_PN=${PN/e/E}
+
+DESCRIPTION="Multi-platform text editor supporting over 50 programming languages"
+HOMEPAGE="http://editra.org http://pypi.python.org/pypi/Editra"
+SRC_URI="http://editra.org/uploads/src/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="wxWinLL-3.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="spell"
+
+DEPEND="
+	>=dev-python/wxpython-2.8.9.2:2.8[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-0.6[${PYTHON_USEDEP}]"
+# setuptools is RDEPEND because it's used by the runtime for installing plugins
+RDEPEND="${DEPEND}
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}"/${MY_PN}-${PV}
+
+python_compile() {
+	# http://code.google.com/p/editra/issues/detail?id=481
+	distutils-r1_python_compile --no-clean
+}
+
+python_install() {
+	distutils-r1_python_install --no-clean
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doicon "${S}"/pixmaps/editra.png
+	make_desktop_entry editra Editra editra "Utility;TextEditor"
+	dodoc FAQ THANKS
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}