Version bump. Drop unused dependency on python, bug #312107.

(Portage version: 2.2_rc67/cvs/Linux i686)

2 files changed, 56 insertions, 1 deletions

diff --git a/app-text/iso-codes/ChangeLog b/app-text/iso-codes/ChangeLog
index 2c51f90a5c86..df57673e7dab 100644
--- a/app-text/iso-codes/ChangeLog
+++ b/app-text/iso-codes/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/iso-codes
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/iso-codes/ChangeLog,v 1.86 2010/03/30 23:17:33 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/iso-codes/ChangeLog,v 1.87 2010/05/17 12:22:34 eva Exp $
+
+*iso-codes-3.16 (17 May 2010)
+
+  17 May 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  +iso-codes-3.16.ebuild:
+  Version bump. Drop unused dependency on python, bug #312107.
 
   30 Mar 2010; Gilles Dartiguelongue <eva@gentoo.org> iso-codes-3.14.ebuild:
   Fix missing || before die, thanks to Arfrever for spotting it.
diff --git a/app-text/iso-codes/iso-codes-3.16.ebuild b/app-text/iso-codes/iso-codes-3.16.ebuild
new file mode 100644
index 000000000000..cded1421ac05
--- /dev/null
+++ b/app-text/iso-codes/iso-codes-3.16.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/iso-codes/iso-codes-3.16.ebuild,v 1.1 2010/05/17 12:22:34 eva Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="Provides the list of country and language names"
+HOMEPAGE="http://alioth.debian.org/projects/pkg-isocodes/"
+SRC_URI="ftp://pkg-isocodes.alioth.debian.org/pub/pkg-isocodes/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE=""
+
+RDEPEND=""
+DEPEND="sys-devel/gettext"
+
+src_prepare() {
+	local linguas_bak=${LINGUAS}
+	local mylinguas=""
+
+	for norm in iso_15924 iso_3166 iso_3166_2 iso_4217 iso_639 iso_639_3; do
+		einfo "Preparing ${norm}"
+
+		mylinguas=""
+		LINGUAS=${linguas_bak}
+		strip-linguas -i "${S}/${norm}"
+
+		for loc in ${LINGUAS}; do
+			mylinguas="${mylinguas} ${loc}.po"
+		done
+
+		if [ -n "${mylinguas}" ]; then
+			sed -e "s:pofiles =.*:pofiles = ${mylinguas}:" \
+				-e "s:mofiles =.*:mofiles = ${mylinguas//.po/.mo}:" \
+				-i "${S}/${norm}/Makefile.am" "${S}/${norm}/Makefile.in" \
+				|| die "sed in ${norm} folder failed"
+		fi
+	done
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "Installation failed"
+
+	dodoc ChangeLog README TODO || die "dodoc failed"
+}