Version bump for Gnome 3.12.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 61 insertions, 1 deletions

diff --git a/gnome-base/libgnome-keyring/ChangeLog b/gnome-base/libgnome-keyring/ChangeLog
index f5f0ac3f5493..f00f46ee60f8 100644
--- a/gnome-base/libgnome-keyring/ChangeLog
+++ b/gnome-base/libgnome-keyring/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/libgnome-keyring
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/ChangeLog,v 1.55 2014/04/26 18:43:00 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/ChangeLog,v 1.56 2014/04/27 17:03:29 eva Exp $
+
+*libgnome-keyring-3.12.0 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org>
+  +libgnome-keyring-3.12.0.ebuild:
+  Version bump for Gnome 3.12.
 
   26 Apr 2014; Pacho Ramos <pacho@gentoo.org> -libgnome-keyring-3.8.0.ebuild:
   drop old
diff --git a/gnome-base/libgnome-keyring/libgnome-keyring-3.12.0.ebuild b/gnome-base/libgnome-keyring/libgnome-keyring-3.12.0.ebuild
new file mode 100644
index 000000000000..22acbf7ebe8e
--- /dev/null
+++ b/gnome-base/libgnome-keyring/libgnome-keyring-3.12.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/libgnome-keyring-3.12.0.ebuild,v 1.1 2014/04/27 17:03:29 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit gnome2 python-any-r1 vala
+
+DESCRIPTION="Compatibility library for accessing secrets"
+HOMEPAGE="http://live.gnome.org/GnomeKeyring"
+
+LICENSE="LGPL-2+ GPL-2+" # tests are GPL-2
+SLOT="0"
+IUSE="debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris"
+
+RDEPEND="
+	>=sys-apps/dbus-1
+	>=gnome-base/gnome-keyring-3.1.92
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+
+	# FIXME: Remove silly CFLAGS, report upstream
+	sed -e 's:CFLAGS="$CFLAGS -g:CFLAGS="$CFLAGS:' \
+		-e 's:CFLAGS="$CFLAGS -O0:CFLAGS="$CFLAGS:' \
+		-i configure.ac configure || die "sed failed"
+}
+
+src_configure() {
+	gnome2_src_configure $(use_enable vala)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	dbus-launch emake check || die "tests failed"
+}