Add logrotate file thanks to DEMAINE Benoît-Pierre <dhp_gentoo@doublehp.org>. Bug #324727

(Portage version: 2.1.11.38/cvs/Linux x86_64, signed Manifest commit with key B4AFF2C2)

1 files changed, 82 insertions, 0 deletions

diff --git a/net-misc/icecast/icecast-2.3.3-r1.ebuild b/net-misc/icecast/icecast-2.3.3-r1.ebuild
new file mode 100644
index 000000000000..6bf9660bc0d4
--- /dev/null
+++ b/net-misc/icecast/icecast-2.3.3-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/icecast/icecast-2.3.3-r1.ebuild,v 1.1 2012/12/23 19:24:09 hwoarang Exp $
+
+EAPI=4
+inherit eutils autotools user
+
+DESCRIPTION="An opensource alternative to shoutcast that supports mp3, ogg (vorbis/theora) and aac streaming"
+HOMEPAGE="http://www.icecast.org/"
+SRC_URI="http://downloads.xiph.org/releases/icecast/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="kate logrotate +speex +ssl +theora +yp"
+
+#Although there is a --with-ogg and --with-orbis configure option, they're
+#only useful for specifying paths, not for disabling.
+DEPEND="dev-libs/libxslt
+	dev-libs/libxml2
+	media-libs/libogg
+	media-libs/libvorbis
+	kate? ( media-libs/libkate )
+	logrotate? ( app-admin/logrotate )
+	speex? ( media-libs/speex )
+	theora? ( media-libs/libtheora )
+	yp? ( net-misc/curl )
+	ssl? ( dev-libs/openssl )"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewuser icecast -1 -1 -1 nogroup
+}
+
+src_prepare() {
+	# bug #368539
+	epatch "${FILESDIR}"/${P}-libkate.patch
+	# bug #430434
+	epatch "${FILESDIR}"/${P}-fix-xiph_openssl.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		--sysconfdir=/etc/icecast2 \
+		$(use_enable kate) \
+		$(use_with theora) \
+		$(use_with speex) \
+		$(use_with yp curl) \
+		$(use_with ssl openssl) \
+		$(use_enable yp)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS README TODO HACKING NEWS conf/icecast.xml.dist
+	dohtml -A chm,hhc,hhp doc/*
+	doman debian/icecast2.1
+
+	newinitd "${FILESDIR}"/init.d.icecast icecast
+
+	insinto /etc/icecast2
+	doins "${FILESDIR}"/icecast.xml
+	fperms 600 /etc/icecast2/icecast.xml
+
+	if use logrotate; then
+		dodir /etc/logrotate.d
+		insopts -m0644
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}"/${PN}.logrotate ${PN}
+	fi
+	diropts -m0764 -o icecast -g nogroup
+	dodir /var/log/icecast
+	keepdir /var/log/icecast
+	rm -rf "${D}"/usr/share/doc/icecast
+}
+
+pkg_postinst() {
+	touch "${ROOT}"var/log/icecast/{access,error}.log
+	chown icecast:nogroup "${ROOT}"var/log/icecast/{access,error}.log
+}