Bump to latest aufs3, genpatches and linux release

(Portage version: 2.2.16/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 91 insertions, 1 deletions

diff --git a/sys-kernel/aufs-sources/ChangeLog b/sys-kernel/aufs-sources/ChangeLog
index 21fb390fd3c0..50b1b23639f5 100644
--- a/sys-kernel/aufs-sources/ChangeLog
+++ b/sys-kernel/aufs-sources/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-kernel/aufs-sources
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.173 2015/02/13 10:02:05 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.174 2015/02/17 07:31:22 jlec Exp $
+
+*aufs-sources-3.19.0 (17 Feb 2015)
+
+  17 Feb 2015; Justin Lecher <jlec@gentoo.org> +aufs-sources-3.19.0.ebuild:
+  Bump to latest aufs3, genpatches and linux release
 
 *aufs-sources-3.18.6-r1 (13 Feb 2015)
 *aufs-sources-3.18.7-r1 (13 Feb 2015)
diff --git a/sys-kernel/aufs-sources/aufs-sources-3.19.0.ebuild b/sys-kernel/aufs-sources/aufs-sources-3.19.0.ebuild
new file mode 100644
index 000000000000..9d2e5746b6cd
--- /dev/null
+++ b/sys-kernel/aufs-sources/aufs-sources-3.19.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/aufs-sources-3.19.0.ebuild,v 1.1 2015/02/17 07:31:22 jlec Exp $
+
+EAPI=5
+
+ETYPE="sources"
+K_WANT_GENPATCHES="base extras experimental"
+K_GENPATCHES_VER="1"
+K_DEBLOB_AVAILABLE="1"
+UNIPATCH_STRICTORDER=1
+inherit kernel-2 eutils readme.gentoo
+detect_version
+detect_arch
+
+AUFS_VERSION=3.19_p20150216
+AUFS_TARBALL="aufs-sources-${AUFS_VERSION}.tar.xz"
+# git archive -v --remote=git://git.code.sf.net/p/aufs/aufs3-standalone aufs${AUFS_VERSION/_p*} > aufs-sources-${AUFS_VERSION}.tar
+AUFS_URI="http://dev.gentoo.org/~jlec/distfiles/${AUFS_TARBALL}"
+
+KEYWORDS="~amd64 ~x86"
+HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
+IUSE="deblob experimental module vanilla"
+
+DESCRIPTION="Full sources including the Gentoo patchset for the ${KV_MAJOR}.${KV_MINOR} kernel tree and aufs3 support"
+SRC_URI="
+	${KERNEL_URI}
+	${ARCH_URI}
+	${AUFS_URI}
+	!vanilla? ( ${GENPATCHES_URI} )
+	"
+
+PDEPEND=">=sys-fs/aufs-util-3.9"
+
+README_GENTOO_SUFFIX="-r1"
+
+src_unpack() {
+	if use vanilla; then
+		unset UNIPATCH_LIST_GENPATCHES UNIPATCH_LIST_DEFAULT
+		ewarn "You are using USE=vanilla"
+		ewarn "This will drop all support from the gentoo kernel security team"
+	fi
+
+	UNIPATCH_LIST="
+		"${WORKDIR}"/aufs3-kbuild.patch
+		"${WORKDIR}"/aufs3-base.patch
+		"${WORKDIR}"/aufs3-mmap.patch"
+
+	use module && UNIPATCH_LIST+=" "${WORKDIR}"/aufs3-standalone.patch"
+
+	unpack ${AUFS_TARBALL}
+
+	einfo "Using aufs3 version: ${AUFS_VERSION}"
+
+	kernel-2_src_unpack
+}
+
+src_prepare() {
+	if ! use module; then
+		sed -e 's:tristate:bool:g' -i "${WORKDIR}"/fs/aufs/Kconfig || die
+	fi
+	cp -f "${WORKDIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
+	cp -rf "${WORKDIR}"/{Documentation,fs} . || die
+}
+
+src_install() {
+	kernel-2_src_install
+	dodoc "${WORKDIR}"/{aufs3-loopback,vfs-ino,tmpfs-idr}.patch
+	docompress -x /usr/share/doc/${PF}/{aufs3-loopback,vfs-ino,tmpfs-idr}.patch
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	kernel-2_pkg_postinst
+	einfo "For more info on this patchset, and how to report problems, see:"
+	einfo "${HOMEPAGE}"
+	has_version sys-fs/aufs-util || \
+		elog "In order to use aufs FS you need to install sys-fs/aufs-util"
+
+	readme.gentoo_pkg_postinst
+}
+
+pkg_postrm() {
+	kernel-2_pkg_postrm
+}