1 files changed, 53 insertions, 0 deletions
diff --git a/net-dialup/pptpclient/pptpclient-1.7.2-r3.ebuild b/net-dialup/pptpclient/pptpclient-1.7.2-r3.ebuild
new file mode 100644
index 000000000000..533037d30859
--- /dev/null
+++ b/net-dialup/pptpclient/pptpclient-1.7.2-r3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/pptpclient/pptpclient-1.7.2-r3.ebuild,v 1.1 2013/05/15 09:35:52 pinkbyte Exp $
+
+EAPI="5"
+
+inherit eutils toolchain-funcs
+
+MY_P="${P/client}"
+MY_CMD="pptp-command-20130515"
+
+DESCRIPTION="Linux client for PPTP"
+HOMEPAGE="http://pptpclient.sourceforge.net/"
+SRC_URI="mirror://sourceforge/pptpclient/${MY_P}.tar.gz
+	http://dev.gentoo.org/~pinkbyte/distfiles/pptpclient/${MY_CMD}.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
+IUSE="tk"
+
+DEPEND="net-dialup/ppp
+	dev-lang/perl
+	tk? ( dev-perl/perl-tk )"
+RDEPEND="${DEPEND}
+	sys-apps/iproute2"
+
+RESTRICT="test" #make test is useless and vector_test.c is broken
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS NEWS README TODO USING )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-process-name.patch
+	epatch_user
+}
+
+src_compile() {
+	emake OPTIMISE= DEBUG= CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+	dodoc Documentation/*
+	dodir /etc/pptp.d
+
+	# The current version of pptp-linux doesn't include the
+	# RH-specific portions, so include them ourselves.
+	newsbin "${WORKDIR}/${MY_CMD}" pptp-command
+	dosbin "${FILESDIR}/pptp_fe.pl"
+	use tk && dosbin "${FILESDIR}/xpptp_fe.pl"
+}