3 files changed, 97 insertions, 6 deletions
diff --git a/net-libs/libproxy/ChangeLog b/net-libs/libproxy/ChangeLog
index bd5c04580af2..d7d4a2545f70 100644
--- a/net-libs/libproxy/ChangeLog
+++ b/net-libs/libproxy/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/libproxy
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.41 2010/10/28 09:20:32 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.42 2010/11/02 09:30:25 ssuominen Exp $
+
+*libproxy-0.4.6-r1 (02 Nov 2010)
+
+  02 Nov 2010; Samuli Suominen <ssuominen@gentoo.org> libproxy-0.4.6.ebuild,
+  +libproxy-0.4.6-r1.ebuild:
+  Disable dev-lang/vala support because it's not ready to be stabilized wrt
+  #343737.
 
   28 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
   files/libproxy-0.4.6-mozjs-link_directory.patch:
diff --git a/net-libs/libproxy/libproxy-0.4.6-r1.ebuild b/net-libs/libproxy/libproxy-0.4.6-r1.ebuild
new file mode 100644
index 000000000000..d1de5256461a
--- /dev/null
+++ b/net-libs/libproxy/libproxy-0.4.6-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/libproxy-0.4.6-r1.ebuild,v 1.1 2010/11/02 09:30:25 ssuominen Exp $
+
+EAPI="2"
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit cmake-utils eutils multilib python portability
+
+DESCRIPTION="Library for automatic proxy configuration management"
+HOMEPAGE="http://code.google.com/p/libproxy/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gnome kde mono networkmanager perl python test vala webkit xulrunner"
+
+RDEPEND="
+	gnome? ( gnome-base/gconf )
+	kde? ( >=kde-base/kdelibs-4.3 )
+	mono? ( dev-lang/mono )
+	networkmanager? ( net-misc/networkmanager )
+	perl? (	dev-lang/perl )
+	vala? ( dev-lang/vala )
+	webkit? ( net-libs/webkit-gtk )
+	xulrunner? ( >=net-libs/xulrunner-1.9.1:1.9 )"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.19"
+
+DOCS="AUTHORS NEWS README ChangeLog"
+
+PATCHES=( "${FILESDIR}"/${P}-mozjs-link_directory.patch )
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+			-DPERL_VENDORINSTALL=ON
+			-DCMAKE_C_FLAGS="${CFLAGS}"
+			-DCMAKE_CXX_FLAGS="${CXXFLAGS}"
+			$(cmake-utils_use_with gnome GNOME)
+			$(cmake-utils_use_with kde KDE4)
+			$(cmake-utils_use_with mono DOTNET)
+			$(cmake-utils_use_with networkmanager NM)
+			$(cmake-utils_use_with perl PERL)
+			$(cmake-utils_use_with python PYTHON)
+			$(cmake-utils_use_with vala VALA)
+			$(cmake-utils_use_with webkit WEBKIT)
+			$(cmake-utils_use_with xulrunner MOZJS)
+			$(cmake-utils_use test BUILD_TESTING)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# Prevent access violation when building with mono support
+	export MONO_SHARED_DIR="${T}/shared"
+	cmake-utils_src_compile
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libproxy.so.0
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libproxy.so.0
+
+	if use python; then
+		python_need_rebuild
+		python_mod_optimize $(python_get_sitedir)/${PN}.py
+	fi
+}
+
+pkg_postrm() {
+	if use python; then
+		python_mod_cleanup $(python_get_sitedir)/${PN}.py
+	fi
+}
diff --git a/net-libs/libproxy/libproxy-0.4.6.ebuild b/net-libs/libproxy/libproxy-0.4.6.ebuild
index e9fb2a3e811b..b0c90419dca8 100644
--- a/net-libs/libproxy/libproxy-0.4.6.ebuild
+++ b/net-libs/libproxy/libproxy-0.4.6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/libproxy-0.4.6.ebuild,v 1.2 2010/09/30 18:08:02 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/libproxy-0.4.6.ebuild,v 1.3 2010/11/02 09:30:25 ssuominen Exp $
 
 EAPI="2"
 PYTHON_DEPEND="python? 2:2.5"
@@ -14,7 +14,7 @@ SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
-IUSE="gnome kde mono networkmanager perl python test vala webkit xulrunner"
+IUSE="gnome kde mono networkmanager perl python test webkit xulrunner"
 
 RDEPEND="
 	gnome? ( gnome-base/gconf )
@@ -22,7 +22,6 @@ RDEPEND="
 	mono? ( dev-lang/mono )
 	networkmanager? ( net-misc/networkmanager )
 	perl? (	dev-lang/perl )
-	vala? ( dev-lang/vala )
 	webkit? ( net-libs/webkit-gtk )
 	xulrunner? ( >=net-libs/xulrunner-1.9.1:1.9 )"
 
@@ -50,11 +49,12 @@ src_configure() {
 			$(cmake-utils_use_with networkmanager NM)
 			$(cmake-utils_use_with perl PERL)
 			$(cmake-utils_use_with python PYTHON)
-			$(cmake-utils_use_with vala VALA)
+			-DWITH_VALA=OFF
 			$(cmake-utils_use_with webkit WEBKIT)
 			$(cmake-utils_use_with xulrunner MOZJS)
 			$(cmake-utils_use test BUILD_TESTING)
-	)
+			)
+
 	cmake-utils_src_configure
 }