# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/xine-ui/xine-ui-0.99.3.ebuild,v 1.8 2005/11/22 10:21:03 flameeyes Exp $

inherit eutils

PATCHLEVEL="1"
DESCRIPTION="Xine movie player"
HOMEPAGE="http://xine.sourceforge.net/"
SRC_URI="mirror://sourceforge/xine/${P}.tar.gz
	mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 amd64 ppc64 ~sparc ~mips"
IUSE="X nls directfb lirc aalib"

DEPEND="media-libs/libpng
	>=media-libs/xine-lib-1_rc8
	>=net-misc/curl-7.10.2
	lirc? ( app-misc/lirc )
	X? ( virtual/x11 )
	aalib? ( media-libs/aalib )
	directfb? ( >=dev-libs/DirectFB-0.9.9 )"
RDEPEND="nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch ${WORKDIR}/${PV}/01_all_true-false.patch
	use directfb || sed -i "s:dfb::" src/Makefile.in
	sed -i "s:LDFLAGS =:LDFLAGS = -L/lib :" src/xitk/Makefile.in
}

src_compile() {
	rm misc/xine-bugreport
	local myconf=""

	use X || myconf="${myconf} --disable-x11 --disable-xv"
	use aalib || sed -e 's:no_aalib="":no_aalib="yes":g' -i configure || die "could not disable aalib"

	econf ${myconf} \
	$(use_enable nls) \
	$(use_enable lirc) \
	|| die "configuration failed!"

	emake || die "Make failed!"
}

src_install() {
	make DESTDIR=${D} docdir=/usr/share/doc/${PF} docsdir=/usr/share/doc/${PF} install || die
	dodoc AUTHORS ChangeLog NEWS README

	rm ${D}/usr/share/xine/desktop/xine.desktop

	insinto /usr/share/applications
	doins ${WORKDIR}/${PV}/xine.desktop
}