app-doc/pms/pms-99999999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/pms-99999999.ebuild,v 1.6 2009/04/13 08:52:59 fauli Exp $

inherit git

EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/pms.git"

DESCRIPTION="Gentoo Package Manager Specification (draft)"
HOMEPAGE="http://www.gentoo.org/proj/en/qa/pms.xml"
SRC_URI=""

LICENSE="CCPL-Attribution-ShareAlike-3.0"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="all-options eapi3-draft html kdebuild"

DEPEND="html? ( dev-tex/tex4ht )
	dev-texlive/texlive-latex
	dev-texlive/texlive-latexrecommended
	dev-texlive/texlive-latexextra
	dev-texlive/texlive-science"
RDEPEND=""

src_unpack() {
	if use eapi3-draft; then
		EGIT_REPO_URI="git://github.com/ciaranm/pms.git"
		EGIT_BRANCH="eapi-3"
		EGIT_TREE="${EGIT_BRANCH}"
	fi
	git_src_unpack
}

set_conditional() {
	local boolname=ENABLE-$(tr '[[:lower:]]' '[[:upper:]]' <<<${1})
	local boolval=$(use ${1} && echo true || echo false)
	sed -i -e '/\\setboolean{'${boolname}'}/s/true\|false/'${boolval}'/' pms.tex || die "sed failed"
}

src_compile() {
	set_conditional all-options
	set_conditional kdebuild

	emake || die "emake failed"
	if use html; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	dodoc pms.pdf || die "dodoc failed"
	if use html; then
		dohtml *.html pms.css $(shopt -s nullglob; echo *.png) || die "dohtml failed"
	fi
}