dev-libs/log4cplus/log4cplus-1.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/log4cplus/log4cplus-1.1.0.ebuild,v 1.2 2013/03/02 20:02:40 hwoarang Exp $

EAPI=5

DESCRIPTION="C++ port of the Log for Java (log4j) logging library"
HOMEPAGE="http://log4cplus.sourceforge.net/"
SRC_URI="mirror://sourceforge/project/${PN}/${PN}-stable/${PV}/${P}.tar.bz2"

LICENSE="|| ( Apache-2.0 BSD-2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="iconv test threads working-locale working-c-locale qt"

REQUIRED_USE="iconv? ( !working-locale !working-c-locale )
	working-locale? ( !iconv !working-c-locale )
	working-c-locale? ( !iconv !working-locale )"

RDEPEND="iconv? ( virtual/libiconv )
	qt? ( dev-qt/qtcore )"
DEPEND="virtual/pkgconfig
	${RDEPEND}"

DOCS="AUTHORS ChangeLog NEWS README TODO docs/unicode.txt"

src_prepare() {
	default

	if ! use test; then
		sed -i -e 's:tests::' Makefile.in || die
	fi
}

src_configure() {
	econf \
		--disable-static \
		$(use_enable threads) \
		$(use_with iconv) \
		$(use_with working-locale) \
		$(use_with working-c-locale) \
		$(use_with qt)
}

src_test() {
	cd tests/

	for dir in appender customloglevel fileappender filter \
		hierarchy loglog ndc ostream patternlayout performance priority \
		propertyconfig timeformat; do
		einfo "Running test \"${dir}_test\""
		pushd "${dir}_test/" 1>/dev/null
		./${dir}_test || die "Running ${dir}_test failed!"
		popd 1>/dev/null
	done

	if use threads; then
		for dir in configandwatch thread; do
			einfo "Running test \"${dir}_test\""
			pushd "${dir}_test/" 1>/dev/null
			./${dir}_test || die "Running ${dir}_test failed!"
			popd 1>/dev/null
		done
	fi
}