games-arcade/rocksndiamonds/rocksndiamonds-3.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/rocksndiamonds/rocksndiamonds-3.1.0.ebuild,v 1.4 2005/04/27 21:38:54 mr_bones_ Exp $

inherit flag-o-matic games

DESCRIPTION="A Boulderdash clone"
HOMEPAGE="http://www.artsoft.org/rocksndiamonds/"
SRC_URI="http://www.artsoft.org/RELEASES/unix/rocksndiamonds/${P}.tar.gz
	http://www.artsoft.org/RELEASES/rocksndiamonds/levels/BD2K3-1.0.0.zip
	http://www.artsoft.org/RELEASES/rocksndiamonds/levels/rnd-contrib-1.0.0.tar.gz
	http://www.artsoft.org/RELEASES/unix/rocksndiamonds/levels/rockslevels-emc-1.0.tar.gz
	http://www.artsoft.org/RELEASES/unix/rocksndiamonds/levels/rockslevels-sp-1.0.tar.gz
	http://www.artsoft.org/RELEASES/unix/rocksndiamonds/levels/rockslevels-dx-1.0.tar.gz
	http://www.jb-line.de/rnd_jue-v5.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc amd64"
IUSE="X sdl"

RDEPEND="virtual/libc
	app-arch/unzip
	X? ( virtual/x11 )
	!sdl? ( virtual/x11 )
	sdl? ( >=media-libs/libsdl-1.2.3
		>=media-libs/sdl-mixer-1.2.4
		media-libs/sdl-net
		>=media-libs/sdl-image-1.2.2 )"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${P}.tar.gz
	cd ${S}
	unpack rockslevels-emc-1.0.tar.gz
	unpack rockslevels-sp-1.0.tar.gz
	unpack rockslevels-dx-1.0.tar.gz

	# make it parallel-friendly.
	sed -i \
		-e 's:\$(MAKE_CMD):$(MAKE) -C $(SRC_DIR):' \
		-e '/^MAKE/d' Makefile \
		|| die "sed Makefile failed"

	cd levels
	unpack rnd_jue-v5.zip
	unpack BD2K3-1.0.0.zip
	unpack rnd-contrib-1.0.0.tar.gz
}

src_compile() {
	replace-cpu-flags k6 k6-1 k6-2 i586

	local makeopts="RO_GAME_DIR=${GAMES_DATADIR}/${PN} RW_GAME_DIR=${GAMES_STATEDIR}/${PN}"
	if use X || { ! use X && ! use sdl; } ; then
		make clean || die
		emake ${makeopts} OPTIONS="${CFLAGS}" x11 || die
		mv rocksndiamonds{,.x11}
	fi
	if use sdl ; then
		make clean || die
		emake ${makeopts} OPTIONS="${CFLAGS}" sdl || die
		mv rocksndiamonds{,.sdl}
	fi
}

src_install() {
	dogamesbin rocksndiamonds.{sdl,x11} || die "dogamesbin failed"
	dodir "${GAMES_DATADIR}/${PN}"
	cp -R graphics levels music sounds ${D}/${GAMES_DATADIR}/${PN}/ \
		|| die "cp failed"

	newman rocksndiamonds.{1,6}
	dodoc CHANGES CREDITS HARDWARE README TODO docs/elements/*.txt

	prepgamesdirs
}