From 6eef71fe0697ab3e9fdef79c864c2982b441c5dc Mon Sep 17 00:00:00 2001
From: Alexey Shvetsov <alexxy@gentoo.org>
Date: Tue, 23 Apr 2019 18:16:57 +0300
Subject: dev-python/flask-babel: Version bump

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Alexey Shvetsov <alexxy@gentoo.org>
---
 dev-python/flask-babel/Manifest                  |  1 +
 dev-python/flask-babel/flask-babel-0.12.2.ebuild | 48 ++++++++++++++++++++++++
 dev-python/flask-babel/metadata.xml              | 13 +++++++
 3 files changed, 62 insertions(+)
 create mode 100644 dev-python/flask-babel/Manifest
 create mode 100644 dev-python/flask-babel/flask-babel-0.12.2.ebuild
 create mode 100644 dev-python/flask-babel/metadata.xml

diff --git a/dev-python/flask-babel/Manifest b/dev-python/flask-babel/Manifest
new file mode 100644
index 0000000..ca114db
--- /dev/null
+++ b/dev-python/flask-babel/Manifest
@@ -0,0 +1 @@
+DIST Flask-Babel-0.12.2.tar.gz 44567 SHA256 316ad183e42003f3922957fa643d0a1e8e34a0f0301a88c3a8f605bc37ba5c86 SHA512 c43bf5cf6c66e3a8a52298f52bd6300cf0b0c53a1f0fb5862b1bcf8a9800ea0e043c9f85125bb9eb5c281a3c0583c63f0f9653792204883a6f82080547b37104 WHIRLPOOL 4ccb6c089c556c0b3d4078a4887e69c6f9eb9f291897eca1e8153087a7c48b6f5cc17b763b4182b14bfa22eb28e039859c3935cada8eb53a2fc134d2ba890cd4
diff --git a/dev-python/flask-babel/flask-babel-0.12.2.ebuild b/dev-python/flask-babel/flask-babel-0.12.2.ebuild
new file mode 100644
index 0000000..2f46f1b
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-0.12.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/'sphinx.ext.intersphinx'//" \
+		-e '/^html_theme =/,/^}/d' docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/flask-babel/metadata.xml b/dev-python/flask-babel/metadata.xml
new file mode 100644
index 0000000..ee71c5b
--- /dev/null
+++ b/dev-python/flask-babel/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">Flask-Babel</remote-id>
+		<remote-id type="github">python-babel/flask-babel</remote-id>
+		<bugs-to>https://github.com/python-babel/flask-babel/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad