app-emacs/haskell-mode: add 17.5

Signed-off-by: Matthew Smith <matthew@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/app-emacs/haskell-mode/haskell-mode-17.5.ebuild b/app-emacs/haskell-mode/haskell-mode-17.5.ebuild
new file mode 100644
index 000000000000..3398482d5f87
--- /dev/null
+++ b/app-emacs/haskell-mode/haskell-mode-17.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Mode for editing (and running) Haskell programs in Emacs"
+HOMEPAGE="https://haskell.github.io/haskell-mode/
+	https://www.haskell.org/haskellwiki/Emacs#Haskell-mode"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/haskell/${PN}.git"
+else
+	SRC_URI="https://github.com/haskell/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-lang/ghc )"
+BDEPEND="sys-apps/texinfo"
+
+ELISP_REMOVE="
+	tests/haskell-cabal-tests.el
+	tests/haskell-customize-tests.el
+	tests/haskell-lexeme-tests.el
+"
+
+DOCS=( NEWS README.md )
+ELISP_TEXINFO="doc/${PN}.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	# We install the logo in SITEETC, not in SITELISP
+	# https://github.com/haskell/haskell-mode/issues/102
+	sed -i -e "/defconst haskell-process-logo/{n;" \
+		-e "s:(.*\"\\(.*\\)\".*):\"${SITEETC}/${PN}/\\1\":}" \
+		haskell-process.el || die
+
+	elisp_src_prepare
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file haskell-site-file.el
+}
+
+src_test() {
+	emake check-ert
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto "${SITEETC}"/${PN}
+	doins logo.svg
+}