dev-libs/libpeas: Version bump to 1.32.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 127 insertions, 0 deletions

diff --git a/dev-libs/libpeas/Manifest b/dev-libs/libpeas/Manifest
index f95810f61148..2ae498a9d073 100644
--- a/dev-libs/libpeas/Manifest
+++ b/dev-libs/libpeas/Manifest
@@ -1 +1,2 @@
 DIST libpeas-1.30.0.tar.xz 193108 BLAKE2B 071e24530934605a6364816165d8f47ac9c94887e80eda9175b163d9af64b2624d42df75c7697220e888f2f9150c6e121bd1dc2716de5bcf0d392722938de945 SHA512 10ebcc61c8aa42b5f6892a74d5e02a52dbc8fe4c35280d78f41adc915dd9c08e9756608f8cbdbaf3d63c44074f0b9e9e531dd077ba201b416acfdcfb94b4bc42
+DIST libpeas-1.32.0.tar.xz 193572 BLAKE2B a29be56dd4add53ac11e52e7a9b6f9aaf1634bec0be6efe33d99fbb1a323cdc2f9d81917f160c3d8f4b88068d13a3b6cc732aa147bba1c1e524ed5eb1e238ad9 SHA512 520a5fd8657f75dc0e28a17ccab88a2952d018f81384eaea0fc65779e66b0ebc79b0dc8ce184e49d43406381c75c2028b402c1bb9d650eae2edf35ec8617a897
diff --git a/dev-libs/libpeas/files/1.32.0-meson-Fix-disabling-gtk_doc.patch b/dev-libs/libpeas/files/1.32.0-meson-Fix-disabling-gtk_doc.patch
new file mode 100644
index 000000000000..39377b392dee
--- /dev/null
+++ b/dev-libs/libpeas/files/1.32.0-meson-Fix-disabling-gtk_doc.patch
@@ -0,0 +1,31 @@
+https://gitlab.gnome.org/GNOME/libpeas/-/merge_requests/34
+
+From 1be9b5a51ca4200d9cff69642368c24225b58dd5 Mon Sep 17 00:00:00 2001
+From: Matt Turner <mattst88@gmail.com>
+Date: Mon, 21 Mar 2022 19:13:04 -0700
+Subject: [PATCH] meson: Fix disabling gtk_doc
+
+Without this, even passing -Dgtk_doc=false will cause documentation to
+be built if gi-docgen is available.
+
+Fixes: 82119a6 ("gi-docgen: Initial commit")
+---
+ meson.build | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/meson.build b/meson.build
+index c77b352..91b8ca8 100644
+--- a/meson.build
++++ b/meson.build
+@@ -251,7 +251,7 @@ configure_file(
+ )
+ 
+ # Options
+-build_gtk_doc = gi_docgen_dep.found()
++build_gtk_doc = get_option('gtk_doc') and gi_docgen_dep.found()
+ 
+ install_glade_catalog = get_option('glade_catalog')
+ if install_glade_catalog and not gladeui_dep.found()
+-- 
+2.34.1
+
diff --git a/dev-libs/libpeas/libpeas-1.32.0.ebuild b/dev-libs/libpeas/libpeas-1.32.0.ebuild
new file mode 100644
index 000000000000..aa4f25fae10e
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.32.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome.org lua-single meson python-single-r1 vala virtualx xdg
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="https://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +gtk gtk-doc lua +python vala"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-1.39:=
+	gtk? ( >=x11-libs/gtk+-3.0.0:3[introspection] )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			>=dev-lua/lgi-0.9.0[${LUA_USEDEP}]
+		')
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.11
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Gentoo-specific lua tweak hack
+	"${FILESDIR}"/1.26.0-lua.patch
+
+	"${FILESDIR}"/${PV}-meson-Fix-disabling-gtk_doc.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature $(usex lua '!lua_single_target_luajit' 'lua') lua51)
+		$(meson_feature $(usex lua 'lua_single_target_luajit' 'lua') luajit)
+		-Dpython2=false
+		$(meson_use python python3)
+		# introspection was always enabled in autotools; would need readiness by consumers
+		# to USE flag it, but most need it for python plugins anyways
+		-Dintrospection=true
+		$(meson_use vala vapi)
+		$(meson_use gtk widgetry)
+		$(meson_use glade glade_catalog)
+		-Ddemos=false
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libpeas{,-gtk}-1.0 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}