games-action/minetest: version bump to 0.4.17.1

Closes: https://bugs.gentoo.org/658570
Closes: https://github.com/gentoo/gentoo/pull/8921

2 files changed, 137 insertions, 0 deletions

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index bff2d6fc0a4a..7117649449e8 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1,2 +1,3 @@
 DIST minetest-0.4.16.tar.gz 7753044 BLAKE2B a35a0bcab00393fc72e5d932a86ebacdd1b3aa5a850e36f7b788599086c65f549341fa05fcbc0c6a09540df79d840611ec352d79e673ba63575a9f51fd5e22af SHA512 c124a997d9eb242885551e5c68948158cbd172ccd44fb1feb4d7aea487f876a2421bc990528dbfb6baf2033bfd4759d17138ed95b077e0ba80785a6e7ff521a2
 DIST minetest-0.4.17.tar.gz 7757149 BLAKE2B 9ee908990224da800e7f0f4fc5e28d5bde03f4486d43ad58225d8ec056f8209fde94597798c977e1d3f3f8cbeadeb0bcdae6eb2aac2b8572fcbcfa28bbd62eba SHA512 3015f5a03be37c5395b55b6dc9f883f9270b19f709a47250f36bc7b1ce6d04a0e89e4366d86da33bbebbfb64f04ff008aec66c96930d7314991a21160265bafe
+DIST minetest-0.4.17.1.tar.gz 7758675 BLAKE2B 93f5f1ce32b98bb78a6ae5bc2ab9110902e118480b37b8c9cf87f1c6aa986f379e1191e82d4a764fb2aa0a0747c113e80cd014e6a06e0a485a59e516c4644fc6 SHA512 9f84ae45ebe181cb1cd2dff6b71b558eb276472efdfcd73bd02a111b2761793d49681bdfbbeaccc28f4a2f49e15b80d04b78db2f2f728c852c188b0c96aae618
diff --git a/games-action/minetest/minetest-0.4.17.1.ebuild b/games-action/minetest/minetest-0.4.17.1.ebuild
new file mode 100644
index 000000000000..b71ccc4d1979
--- /dev/null
+++ b/games-action/minetest/minetest-0.4.17.1.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils gnome2-utils user
+
+DESCRIPTION="An InfiniMiner/Minecraft inspired game"
+HOMEPAGE="https://www.minetest.net"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+curl dedicated doc jsoncpp +leveldb luajit ncurses nls postgres redis +server +sound spatial +truetype"
+
+RDEPEND="dev-db/sqlite:3
+	sys-libs/zlib
+	curl? ( net-misc/curl )
+	!dedicated? (
+		app-arch/bzip2
+		>=dev-games/irrlicht-1.8-r2
+		dev-libs/gmp:0=
+		media-libs/libpng:0=
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg:=
+			media-libs/libvorbis:=
+			media-libs/openal:=
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	jsoncpp? ( dev-libs/jsoncpp )
+	leveldb? ( dev-libs/leveldb:= )
+	luajit? ( dev-lang/luajit:2 )
+	ncurses? ( sys-libs/ncurses:0= )
+	nls? ( virtual/libintl )
+	postgres? ( >=dev-db/postgresql-9.5:= )
+	redis? ( dev-libs/hiredis )
+	spatial? ( sci-libs/libspatialindex )"
+DEPEND="${RDEPEND}
+	>=dev-games/irrlicht-1.8-r2
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use server || use dedicated ; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# set paths
+	sed \
+		-e "s#@BINDIR@#${EPREFIX}/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex !dedicated)
+		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
+		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_LUAJIT=$(usex luajit)
+		-DENABLE_POSTGRESQL=$(usex postgres)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_SYSTEM_JSONCPP=$(usex jsoncpp)
+		-DRUN_IN_PLACE=0
+	)
+
+	use dedicated && mycmakeargs+=(
+		-DIRRLICHT_INCLUDE_DIR="${EPREFIX}/usr/include/irrlicht"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc ; then
+		cmake-utils_src_compile doc
+		HTML_DOCS=( "${CMAKE_BUILD_DIR}"/doc/html/. )
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use server || use dedicated ; then
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+		newconfd "${T}"/minetestserver.confd minetest-server
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+
+	if ! use dedicated ; then
+		elog
+		elog "optional dependencies:"
+		elog "	games-action/minetest_game (official mod)"
+		elog
+	fi
+
+	if use server || use dedicated ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog "The user \"minetest\" is created with /var/lib/${PN} homedir."
+		elog "Default logfile is ~/minetest-server.log"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}