gui-libs/gtksourceview: Version bump to 5.6.2

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29078
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index d0b3da82478f..28528f887dba 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1 +1,2 @@
 DIST gtksourceview-5.6.1.tar.xz 1261200 BLAKE2B 144876e1649087d68aff7b9c33a5de25960672f81e85a2bca9fc3e39ba238b5045965f3b267022d037c7881ecf6713290d3ce850c5a3d67d683a76b3cd92aec9 SHA512 1b3683196fc50b8db56b7ae5161bf94b383361d4364142f4a8e89ab621d700144226871431820cb0bc21d5ec6ff041c75ba7585c6fc575bd532cb7a5dc711628
+DIST gtksourceview-5.6.2.tar.xz 1262272 BLAKE2B c2b2c9e8700d25472521188d034763f23eaa45ec02955bd045094c709169c89cfc9bc37bd66de7837fb61fa442123bb068c016cd183897f3ae49d05fa9212cf1 SHA512 82921af3e7eacf05b86310a9d9d96f8d21c215852f1bb2b38a9d4afe1fbb100b215761666a43a455fbd880d5d0b6bc1acccb8b3a4229bff55275b7978a69f077
diff --git a/gui-libs/gtksourceview/gtksourceview-5.6.2.ebuild b/gui-libs/gtksourceview/gtksourceview-5.6.2.ebuild
new file mode 100644
index 000000000000..ae20e4cb2fd6
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.6.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.6:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test --timeout-multiplier=2
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}