mail-filter/policyd-weight: migrate to glep 81

Closes: https://bugs.gentoo.org/781314
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/mail-filter/policyd-weight/policyd-weight-0.1.15.2-r3.ebuild b/mail-filter/policyd-weight/policyd-weight-0.1.15.2-r3.ebuild
new file mode 100644
index 000000000000..ad62cc4de1a5
--- /dev/null
+++ b/mail-filter/policyd-weight/policyd-weight-0.1.15.2-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit tmpfiles
+
+PATCH_VER="1.0"
+
+DESCRIPTION="Weighted Policy daemon for Postfix"
+HOMEPAGE="http://www.policyd-weight.org/"
+SRC_URI="
+	http://www.policyd-weight.org/releases/${P}.tar.gz
+	mirror://gentoo/${P}-patches-${PATCH_VER}.tar.xz
+	https://dev.gentoo.org/~whissi/dist/${PN}/${P}-patches-${PATCH_VER}.tar.xz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 x86"
+
+RDEPEND="
+	acct-group/polw
+	acct-user/polw
+	dev-perl/Net-DNS
+	dev-perl/Net-IP
+	mail-mta/postfix
+	virtual/perl-File-Spec
+	virtual/perl-Sys-Syslog
+"
+
+src_prepare() {
+	default
+	eapply "${WORKDIR}"/patches/*.patch
+}
+
+src_compile() { :; }
+
+src_install() {
+	exeinto /usr/libexec/postfix
+	doexe policyd-weight
+	fowners root:wheel /usr/libexec/postfix/policyd-weight
+
+	doman man/man5/*.5 man/man8/*.8
+	dodoc *.txt
+
+	insinto /etc
+	newins policyd-weight.conf.sample policyd-weight.conf
+
+	newinitd "${FILESDIR}"/policyd-weight.init.d-r2 policyd-weight
+
+	newtmpfiles "${FILESDIR}"/policyd-weight.tmpfile policyd-weight.conf
+}
+
+pkg_postinst() {
+	tmpfiles_process policyd-weight.conf
+}