media-libs/libyami: Initial import. Ebuild by me.

Package-Manager: portage-2.2.23

4 files changed, 222 insertions, 0 deletions

diff --git a/media-libs/libyami/Manifest b/media-libs/libyami/Manifest
new file mode 100644
index 000000000000..cdd7bb9a6a02
--- /dev/null
+++ b/media-libs/libyami/Manifest
@@ -0,0 +1 @@
+DIST libyami-0.3.0.tar.gz 484586 SHA256 67064558999d63185025a6d63d08458375003bb86369abca50aca97fd2c63acb SHA512 691cbe90840d8cb30da958bb6621434c9962ae6cbfc75b016454570c303a01e7a465baa8622368cf1ef1c670dbc861fb1d49e0c414d684feae04ea742e8e0599 WHIRLPOOL d842f1ce57d40894b80f868934d687603014b6460bdbd274b64893d8f290f8a6a779239f931beb759a7fb8e5ed1649b90fb545391c1d9c8395bb05f6600218d2
diff --git a/media-libs/libyami/libyami-0.3.0.ebuild b/media-libs/libyami/libyami-0.3.0.ebuild
new file mode 100644
index 000000000000..3951d2f79326
--- /dev/null
+++ b/media-libs/libyami/libyami-0.3.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM=git-r3
+	EGIT_REPO_URI="https://github.com/01org/libyami"
+fi
+
+inherit ${SCM} autotools multilib-minimal
+
+DESCRIPTION="Yet Another Media Infrastructure: Media codec with hardware acceleration"
+HOMEPAGE="https://github.com/01org/libyami"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/01org/libyami/archive/${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${P}"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+capi debug dmabuf doc ffmpeg gles +glx libav md5 tools v4l X"
+
+RDEPEND="
+	>=x11-libs/libva-1.6[drm,X?,${MULTILIB_USEDEP}]
+	v4l? (
+		glx? (
+			>=x11-libs/libva-1.6[X,${MULTILIB_USEDEP}]
+			>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+			>=virtual/opengl-7[${MULTILIB_USEDEP}]
+		)
+		!glx? ( >=media-libs/mesa-10[egl,${MULTILIB_USEDEP}] )
+		>=media-libs/libv4l-1.6.2[${MULTILIB_USEDEP}]
+	)
+	X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:0=[${MULTILIB_USEDEP}] )
+		libav? ( media-video/libav:=[${MULTILIB_USEDEP}] )
+	)
+	md5? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
+	dmabuf? ( x11-libs/libdrm[${MULTILIB_USEDEP}] )
+	tools? (
+		gles? ( >=media-libs/mesa-10[egl,gles2,${MULTILIB_USEDEP}] )
+		v4l? ( !glx? ( >=media-libs/mesa-10[egl,gles2,${MULTILIB_USEDEP}] ) )
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable debug) \
+		$(multilib_native_use_enable tools tests) \
+		$(use gles && multilib_native_use_enable tools tests-gles) \
+		$(use_enable v4l v4l2) \
+		$(usex v4l $(use_enable glx v4l2-glx) "--disable-v4l2-glx") \
+		$(use_enable capi) \
+		$(use_enable X x11) \
+		$(use_enable dmabuf) \
+		$(use_enable ffmpeg avformat) \
+		$(use_enable md5) \
+		$(multilib_native_use_enable doc docs) \
+		--enable-vp8dec \
+		--enable-vp9dec \
+		--enable-jpegdec \
+		--enable-h264dec \
+		--disable-h265dec \
+		--enable-h264enc \
+		--enable-jpegenc \
+		--enable-vp8enc \
+		--enable-h265enc
+
+	# h265 decoder doesnt build here with gcc 5.2
+}
+
+multilib_src_compile() {
+	emake
+	multilib_is_native_abi && use doc && emake -C doc
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	multilib_is_native_abi && use doc && dohtml -r doc/html/*
+}
+
+src_install() {
+	multilib-minimal_src_install
+	find "${ED}" -name '*.la' -delete
+}
diff --git a/media-libs/libyami/libyami-9999.ebuild b/media-libs/libyami/libyami-9999.ebuild
new file mode 100644
index 000000000000..3951d2f79326
--- /dev/null
+++ b/media-libs/libyami/libyami-9999.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM=git-r3
+	EGIT_REPO_URI="https://github.com/01org/libyami"
+fi
+
+inherit ${SCM} autotools multilib-minimal
+
+DESCRIPTION="Yet Another Media Infrastructure: Media codec with hardware acceleration"
+HOMEPAGE="https://github.com/01org/libyami"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/01org/libyami/archive/${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${P}"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+capi debug dmabuf doc ffmpeg gles +glx libav md5 tools v4l X"
+
+RDEPEND="
+	>=x11-libs/libva-1.6[drm,X?,${MULTILIB_USEDEP}]
+	v4l? (
+		glx? (
+			>=x11-libs/libva-1.6[X,${MULTILIB_USEDEP}]
+			>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+			>=virtual/opengl-7[${MULTILIB_USEDEP}]
+		)
+		!glx? ( >=media-libs/mesa-10[egl,${MULTILIB_USEDEP}] )
+		>=media-libs/libv4l-1.6.2[${MULTILIB_USEDEP}]
+	)
+	X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:0=[${MULTILIB_USEDEP}] )
+		libav? ( media-video/libav:=[${MULTILIB_USEDEP}] )
+	)
+	md5? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
+	dmabuf? ( x11-libs/libdrm[${MULTILIB_USEDEP}] )
+	tools? (
+		gles? ( >=media-libs/mesa-10[egl,gles2,${MULTILIB_USEDEP}] )
+		v4l? ( !glx? ( >=media-libs/mesa-10[egl,gles2,${MULTILIB_USEDEP}] ) )
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable debug) \
+		$(multilib_native_use_enable tools tests) \
+		$(use gles && multilib_native_use_enable tools tests-gles) \
+		$(use_enable v4l v4l2) \
+		$(usex v4l $(use_enable glx v4l2-glx) "--disable-v4l2-glx") \
+		$(use_enable capi) \
+		$(use_enable X x11) \
+		$(use_enable dmabuf) \
+		$(use_enable ffmpeg avformat) \
+		$(use_enable md5) \
+		$(multilib_native_use_enable doc docs) \
+		--enable-vp8dec \
+		--enable-vp9dec \
+		--enable-jpegdec \
+		--enable-h264dec \
+		--disable-h265dec \
+		--enable-h264enc \
+		--enable-jpegenc \
+		--enable-vp8enc \
+		--enable-h265enc
+
+	# h265 decoder doesnt build here with gcc 5.2
+}
+
+multilib_src_compile() {
+	emake
+	multilib_is_native_abi && use doc && emake -C doc
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	multilib_is_native_abi && use doc && dohtml -r doc/html/*
+}
+
+src_install() {
+	multilib-minimal_src_install
+	find "${ED}" -name '*.la' -delete
+}
diff --git a/media-libs/libyami/metadata.xml b/media-libs/libyami/metadata.xml
new file mode 100644
index 000000000000..7e7aee614369
--- /dev/null
+++ b/media-libs/libyami/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>video</herd>
+  <maintainer>
+    <email>media-video@gentoo.org</email>
+  </maintainer>
+  <use>
+	  <flag name="v4l">Add support for V4L2 hardware codecs.</flag>
+	  <flag name="glx">Add support for OpenGL/GLX instead of EGL.</flag>
+	  <flag name="gles">Add suppport for GLES.</flag>
+	  <flag name="capi">Add a C API interface, in addition to the C++.</flag>
+	  <flag name="md5">Add support for generating md5 sums for each frame.</flag>
+	  <flag name="dmabuf">Enable dma_buf buffer sharing.</flag>
+	  <flag name="tools">Build and install command line tools. Useful for testing.</flag>
+  </use>
+</pkgmetadata>