net-dialup/minicom: fix installation without gettext

If gettext is not installed, eautoreconf breaks the package.  Embed
required m4 files to fix this.

Closes: https://bugs.gentoo.org/912459
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/net-dialup/minicom/Manifest b/net-dialup/minicom/Manifest
index 56424c22667d..d3663f81bd2c 100644
--- a/net-dialup/minicom/Manifest
+++ b/net-dialup/minicom/Manifest
@@ -1 +1,2 @@
 DIST minicom-2.8.tar.gz 948015 BLAKE2B 007a2975a996e2dd2390b1cf20e1a70c4bb1b57d224211d30e8d83a9d02a45c147df34bf409961a20ad3746cb6b5551c1e0702a05bb0a0a3f7f042d251b553be SHA512 5ced0ff79cec11464154561130ddc6a38865170d4e4d80185ada540ba173fe89e35703b6d7fd0cf86caef6e020fcad1d7b1fdb4d4f55e3ddb906aea6a4b81b36
+DIST minicom-m4-2.8.tar.bz2 26016 BLAKE2B 0cff0bc3ca134b417fdabb5e2994afebaf89224b95c0b3843ec57e815f43778c8eab1f8df6098d756616a0c494812d9fabc4292eaeaa9c09afb62821ce852438 SHA512 d09e141b1b83f215dc11dcd33d0cd62000c46384ea86084edfb07b04a4d30c0d9e2dce49e5e8e78f3f70fb646737f1e55a9c1158906312575ca2f02db6283994
diff --git a/net-dialup/minicom/minicom-2.8-r3.ebuild b/net-dialup/minicom/minicom-2.8-r3.ebuild
new file mode 100644
index 000000000000..cd9a960d5175
--- /dev/null
+++ b/net-dialup/minicom/minicom-2.8-r3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Serial Communication Program"
+HOMEPAGE="https://salsa.debian.org/minicom-team/minicom"
+SRC_URI="
+	https://salsa.debian.org/${PN}-team/${PN}/-/archive/${PV}/${P}.tar.gz
+	https://dev.gentoo.org/~ceamac/${CATEGORY}/${PN}/${PN}-m4-${PV}.tar.bz2
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+DEPEND="sys-libs/ncurses:="
+
+RDEPEND="
+	${DEPEND}
+	net-dialup/lrzsz
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.8-gentoo-runscript.patch
+	"${FILESDIR}"/${PN}-2.8-lockdir.patch
+)
+
+src_prepare() {
+	default
+
+	# 912459
+	# Embed the needed m4 macros if gettext is not installed
+	mv "${WORKDIR}"/m4 . || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# Lockdir must exist if not manually specified.
+	# '/var/lock' is created by OpenRC.
+	local myeconfargs=(
+		# See bug #788142
+		--sysconfdir="${EPREFIX}"/etc/${PN}
+
+		--disable-rpath
+		--enable-lock-dir="/var/lock"
+		$(use_enable nls)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# Needs to match --sysconfdir above
+	insinto /etc/minicom
+	doins "${FILESDIR}"/minirc.dfl
+}