proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 61 insertions, 0 deletions

diff --git a/net-dns/knot/knot-1.5.3.ebuild b/net-dns/knot/knot-1.5.3.ebuild
new file mode 100644
index 000000000000..77b523f63892
--- /dev/null
+++ b/net-dns/knot/knot-1.5.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+EGIT_REPO_URI="https://gitlab.labs.nic.cz/labs/${PN}.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+inherit eutils user
+
+DESCRIPTION="High-performance authoritative-only DNS server"
+HOMEPAGE="http://www.knot-dns.cz/"
+[[ ${PV} == 9999 ]] || SRC_URI="https://secure.nic.cz/files/knot-dns/${P/_/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~x86"
+IUSE="debug caps +fastparser idn"
+
+RDEPEND="
+	dev-libs/openssl
+	dev-libs/userspace-rcu
+	caps? ( sys-libs/libcap-ng )
+	idn? ( net-dns/libidn )
+"
+#	sys-libs/glibc
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	virtual/yacc
+	fastparser? ( dev-util/ragel )
+"
+
+S="${WORKDIR}/${P/_/-}"
+
+src_prepare() {
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-storage="${EPREFIX}/var/lib/${PN}" \
+		--with-rundir="${EPREFIX}/var/run/${PN}" \
+		--disable-lto \
+		--enable-recvmmsg \
+		$(use_enable fastparser) \
+		$(use_enable debug debug server,zones,xfr,packet,dname,rr,ns,hash,compiler) \
+		$(use_enable debug debuglevel details) \
+		$(use_with idn libidn)
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/knot.init" knot
+}
+
+pkg_postinst() {
+	enewgroup knot 53
+	enewuser knot 53 -1 /var/lib/knot knot
+}