proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

4 files changed, 114 insertions, 0 deletions

diff --git a/net-libs/libdmapsharing/Manifest b/net-libs/libdmapsharing/Manifest
new file mode 100644
index 000000000000..fb15c994ef30
--- /dev/null
+++ b/net-libs/libdmapsharing/Manifest
@@ -0,0 +1,2 @@
+DIST libdmapsharing-2.9.30.tar.gz 745913 SHA256 6c3917aac7de23999094a5d1ee463cd1b07053a8fcd5c6137b4284447b707e40 SHA512 6c47f8882e14d5a753725884f4e98ee203e29a11cc5882e2beb4b4d1a495e20283be4d7801e45e4078d21ccc6b6601d8d95e262d229adc7b728f8bdbd949154e WHIRLPOOL 3e5b65e9388a438efabeb59bb9961ab997b37711f12fcad19c24b0d07fc1cfe7a81f00f7af7916b3d142072a3dab0cadfe50452e0b1cbd51b028ec2c0e413ab4
+DIST libdmapsharing-2.9.31.tar.gz 746372 SHA256 9c933ee15c89bc4ea0c3455d341ceb66e9f7705c94c32d485bc4b162f4f55b29 SHA512 36e2771f546ff42e437b6e3f0bb2cd11d5e75a34479f07277aa5f044f074bd0a2d20ff45660ebc73956c2ce64b5bd0bd50288cc1c875dc98ee0b44ed93f17b38 WHIRLPOOL 0a8f7b09818947bdadaf87ea05d158ca5de2945e7eb077dff1ecd31a616c86203a0de4694e2b19d0a60a887e3113c566f50765a46514cdf7a93ec55fc9bf5b29
diff --git a/net-libs/libdmapsharing/libdmapsharing-2.9.30.ebuild b/net-libs/libdmapsharing/libdmapsharing-2.9.30.ebuild
new file mode 100644
index 000000000000..1a1d37143a88
--- /dev/null
+++ b/net-libs/libdmapsharing/libdmapsharing-2.9.30.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+DESCRIPTION="A library that implements the DMAP family of protocols"
+HOMEPAGE="http://www.flyn.org/projects/libdmapsharing"
+SRC_URI="http://www.flyn.org/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="3.0/2"
+KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
+IUSE="+introspection test"
+
+# Vala/libgee/gtk+:2 is only used when maintainer-mode is enabled
+# Doesn't seem to be used for anything...
+# TODO: implement tests (requires dev-libs/check)
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	x11-libs/gdk-pixbuf:2
+
+	>=net-dns/avahi-0.6
+	>=net-libs/libsoup-2.32:2.4
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+
+	sys-libs/zlib
+
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+src_prepare() {
+	# Remove useless CFLAGS alteration in configure
+	sed -e 's/CFLAGS -O2/CFLAGS/' \
+		-i configure.ac configure || die
+}
+
+src_configure() {
+	econf \
+		--disable-gtk-doc \
+		--disable-maintainer-mode \
+		--with-mdns=avahi \
+		$(use_enable introspection) \
+		$(use_enable test tests)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
diff --git a/net-libs/libdmapsharing/libdmapsharing-2.9.31.ebuild b/net-libs/libdmapsharing/libdmapsharing-2.9.31.ebuild
new file mode 100644
index 000000000000..75cf4e844028
--- /dev/null
+++ b/net-libs/libdmapsharing/libdmapsharing-2.9.31.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="A library that implements the DMAP family of protocols"
+HOMEPAGE="http://www.flyn.org/projects/libdmapsharing"
+SRC_URI="http://www.flyn.org/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="3.0/2"
+KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
+IUSE="+introspection test"
+
+# Vala/libgee/gtk+:2 is only used when maintainer-mode is enabled
+# Doesn't seem to be used for anything...
+# TODO: implement tests (requires dev-libs/check)
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	x11-libs/gdk-pixbuf:2
+	>=net-dns/avahi-0.6
+	>=net-libs/libsoup-2.32:2.4
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	sys-libs/zlib
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+src_prepare() {
+	# Remove useless CFLAGS alteration in configure
+	sed -e 's/CFLAGS -O2/CFLAGS/' \
+		-i configure.ac configure || die
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-mdns=avahi \
+		$(use_enable introspection) \
+		$(use_enable test tests)
+}
diff --git a/net-libs/libdmapsharing/metadata.xml b/net-libs/libdmapsharing/metadata.xml
new file mode 100644
index 000000000000..da6fd63d0085
--- /dev/null
+++ b/net-libs/libdmapsharing/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>gnome</herd>
+</pkgmetadata>