net-libs/onion: bump to 0.8; bug #582534

Package-Manager: portage-2.2.28

4 files changed, 75 insertions, 0 deletions

diff --git a/net-libs/onion/Manifest b/net-libs/onion/Manifest
index 270ebb827f9f..7206e3c48c63 100644
--- a/net-libs/onion/Manifest
+++ b/net-libs/onion/Manifest
@@ -1 +1,2 @@
 DIST onion-0.7.tar.gz 287822 SHA256 18785a462ea2d7214df8413de86eba2d74e414dace9716a2a7ce7b1cb3d4edb7 SHA512 9da45100ec91893e43c62cdabc1b022dc60fd2b509e387ce12fea69495fc68084afcc2534693955d340352cafc58e98a901a5ef981d1c92793ab15b7b6257d4c WHIRLPOOL e7d0695c2d45ac80edd271eaef0148474c12f1b53777714719af2bdd6d0b0d0c8375ecdc19990ee38f6dc2a31c2f7a19b7b70a4c3ac1a1fbef3548d1a923dad3
+DIST onion-0.8.tar.gz 344347 SHA256 9708ba74b6727fa2fef219a821241f21a661ea9a30611213b0133e7effab1b17 SHA512 c40a36346de7dee6e98d0b5c38b5e133606046e29bacb06a0055a361013077ec0f6adb04dfcbf2f4ce0b72317c9ed918573299aed8760f069dcfd7c211a302d7 WHIRLPOOL 7bdb11b950cddcc948609b6e3d9278e3ba1a17956bf2997fa5aaa62b7c0a8b2b5a023aff3a49ef0625a9a53cf3289f2446655b2c2cf015568c46bfbde1306f29
diff --git a/net-libs/onion/metadata.xml b/net-libs/onion/metadata.xml
index 6ddfc7722b79..c10c1a61f399 100644
--- a/net-libs/onion/metadata.xml
+++ b/net-libs/onion/metadata.xml
@@ -9,6 +9,7 @@
     <flag name="libev">Use <pkg>dev-libs/libev</pkg> as thread poller instead of Linux's epoll.</flag>
     <flag name="libevent">Use <pkg>dev-libs/libevent</pkg> as thread poller instead of libev or Linux's epoll.</flag>
     <flag name="boehm-gc">Add <pkg>dev-libs/boehm-gc</pkg> support for memory allocations.</flag>
+	<flag name="redis">Add support for redis sessions.</flag>
   </use>
   <upstream>
     <remote-id type="github">davidmoreno/onion</remote-id>
diff --git a/net-libs/onion/onion-0.8.ebuild b/net-libs/onion/onion-0.8.ebuild
new file mode 100644
index 000000000000..73d8b540773d
--- /dev/null
+++ b/net-libs/onion/onion-0.8.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/davidmoreno/onion"
+fi
+
+inherit ${SCM} cmake-utils
+
+DESCRIPTION="C library to create simple HTTP servers and Web Applications"
+HOMEPAGE="http://www.coralbits.com/libonion/ https://github.com/davidmoreno/onion"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/davidmoreno/onion/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="|| ( GPL-2+ Apache-2.0 ) AGPL-3"
+SLOT="0"
+IUSE="
+	gnutls pam png jpeg xml systemd sqlite boehm-gc
+	test examples cxx -libev -libevent
+	redis
+"
+
+RDEPEND="
+	gnutls? ( net-libs/gnutls dev-libs/libgcrypt:0= )
+	pam? ( virtual/pam )
+	png? ( media-libs/libpng:0= x11-libs/cairo )
+	jpeg? ( virtual/jpeg:0 )
+	xml? ( dev-libs/libxml2:2 sys-libs/zlib )
+	systemd? ( sys-apps/systemd )
+	sqlite? ( dev-db/sqlite:3 )
+	boehm-gc? ( dev-libs/boehm-gc )
+	libev? ( dev-libs/libev )
+	!libev? ( libevent? ( dev-libs/libevent ) )
+	redis? ( dev-libs/hiredis )
+"
+DEPEND="${RDEPEND}
+	test? ( net-misc/curl )
+"
+REQUIRED_USE="test? ( examples )"
+
+src_configure() {
+	use test || echo '' > tests/CMakeLists.txt
+	local mycmakeargs=(
+		"-DONION_USE_SSL=$(usex gnutls)"
+		"-DONION_USE_PAM=$(usex pam)"
+		"-DONION_USE_PNG=$(usex png)"
+		"-DONION_USE_JPEG=$(usex jpeg)"
+		"-DONION_USE_XML2=$(usex xml)"
+		"-DONION_USE_SYSTEMD=$(usex systemd)"
+		"-DONION_USE_SQLITE3=$(usex sqlite)"
+		"-DONION_USE_GC=$(usex boehm-gc)"
+		"-DONION_USE_TESTS=$(usex test)"
+		"-DONION_EXAMPLES=$(usex examples)"
+		"-DONION_USE_BINDINGS_CPP=$(usex cxx)"
+		"-DONION_USE_REDIS=$(usex redis)"
+		"-DONION_POLLER=$(usex libev libev "$(usex libevent libevent default)")"
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-libs/onion/onion-9999.ebuild b/net-libs/onion/onion-9999.ebuild
index 405fa7b99ae4..73d8b540773d 100644
--- a/net-libs/onion/onion-9999.ebuild
+++ b/net-libs/onion/onion-9999.ebuild
@@ -28,6 +28,7 @@ SLOT="0"
 IUSE="
 	gnutls pam png jpeg xml systemd sqlite boehm-gc
 	test examples cxx -libev -libevent
+	redis
 "
 
 RDEPEND="
@@ -41,6 +42,7 @@ RDEPEND="
 	boehm-gc? ( dev-libs/boehm-gc )
 	libev? ( dev-libs/libev )
 	!libev? ( libevent? ( dev-libs/libevent ) )
+	redis? ( dev-libs/hiredis )
 "
 DEPEND="${RDEPEND}
 	test? ( net-misc/curl )
@@ -61,6 +63,7 @@ src_configure() {
 		"-DONION_USE_TESTS=$(usex test)"
 		"-DONION_EXAMPLES=$(usex examples)"
 		"-DONION_USE_BINDINGS_CPP=$(usex cxx)"
+		"-DONION_USE_REDIS=$(usex redis)"
 		"-DONION_POLLER=$(usex libev libev "$(usex libevent libevent default)")"
 	)
 	cmake-utils_src_configure