From dfb9674fe7d1123bf213c8ea9bdb28e96d5ee5f3 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 31 Dec 2022 13:25:54 +0000
Subject: sys-apps/sandbox: add blocker on older versions of sys-apps/file to
 2.30-r1

My distaste for blockers-as-a-dependency limit are well known, but this
is still useful for a specific case where someone is partially upgrading
and therefore doesn't get the Portage upgrade which has a proper >= dep.

It serves as a notice that they need to upgrade file, which is good enough.

It's worth doing this because of how severe file not working can be.

Bug: https://bugs.gentoo.org/889046
Signed-off-by: Sam James <sam@gentoo.org>
---
 sys-apps/sandbox/sandbox-2.30-r1.ebuild | 64 +++++++++++++++++++++++++++++++++
 sys-apps/sandbox/sandbox-2.30.ebuild    | 61 -------------------------------
 2 files changed, 64 insertions(+), 61 deletions(-)
 create mode 100644 sys-apps/sandbox/sandbox-2.30-r1.ebuild
 delete mode 100644 sys-apps/sandbox/sandbox-2.30.ebuild

diff --git a/sys-apps/sandbox/sandbox-2.30-r1.ebuild b/sys-apps/sandbox/sandbox-2.30-r1.ebuild
new file mode 100644
index 000000000000..7a018dc315d1
--- /dev/null
+++ b/sys-apps/sandbox/sandbox-2.30-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic multilib-minimal multiprocessing
+
+DESCRIPTION="sandbox'd LD_PRELOAD hack"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Sandbox"
+SRC_URI="https://dev.gentoo.org/~floppym/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+nnp"
+
+# pax-utils lower bound for bug #265376
+DEPEND=">=app-misc/pax-utils-0.1.19"
+# Avoid folks installing with older file, bug #889046. We still need the
+# >= dep in Portage but this is a safety net if people do partial upgrades.
+RDEPEND="!<sys-apps/file-5.44-r1"
+BDEPEND="app-arch/xz-utils"
+
+has sandbox_death_notice ${EBUILD_DEATH_HOOKS} || EBUILD_DEATH_HOOKS+=" sandbox_death_notice"
+
+sandbox_death_notice() {
+	ewarn "If configure failed with a 'cannot run C compiled programs' error, try this:"
+	ewarn "FEATURES='-sandbox -usersandbox' emerge sandbox"
+}
+
+src_prepare() {
+	default
+
+	if ! use nnp ; then
+		sed -i 's:PR_SET_NO_NEW_PRIVS:___disable_nnp_hack:' src/sandbox.c || die
+	fi
+
+	# sandbox uses `__asm__ (".symver "...` which does
+	# not play well with gcc's LTO: https://gcc.gnu.org/PR48200
+	filter-lto
+}
+
+multilib_src_configure() {
+	filter-lfs-flags #90228
+
+	ECONF_SOURCE="${S}" econf
+}
+
+multilib_src_test() {
+	# Default sandbox build will run with --jobs set to # cpus.
+	emake check TESTSUITEFLAGS="--jobs=$(makeopts_jobs)"
+}
+
+multilib_src_install_all() {
+	doenvd "${FILESDIR}"/09sandbox
+
+	dodoc AUTHORS ChangeLog* README.md
+}
+
+pkg_postinst() {
+	mkdir -p "${EROOT}"/var/log/sandbox
+	chown root:portage "${EROOT}"/var/log/sandbox
+	chmod 0770 "${EROOT}"/var/log/sandbox
+}
diff --git a/sys-apps/sandbox/sandbox-2.30.ebuild b/sys-apps/sandbox/sandbox-2.30.ebuild
deleted file mode 100644
index 806b5e640d9c..000000000000
--- a/sys-apps/sandbox/sandbox-2.30.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-inherit flag-o-matic multilib-minimal multiprocessing
-
-DESCRIPTION="sandbox'd LD_PRELOAD hack"
-HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Sandbox"
-SRC_URI="https://dev.gentoo.org/~floppym/dist/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-IUSE="+nnp"
-
-# pax-utils lower bound for bug #265376
-DEPEND=">=app-misc/pax-utils-0.1.19"
-BDEPEND="app-arch/xz-utils"
-
-has sandbox_death_notice ${EBUILD_DEATH_HOOKS} || EBUILD_DEATH_HOOKS+=" sandbox_death_notice"
-
-sandbox_death_notice() {
-	ewarn "If configure failed with a 'cannot run C compiled programs' error, try this:"
-	ewarn "FEATURES='-sandbox -usersandbox' emerge sandbox"
-}
-
-src_prepare() {
-	default
-
-	if ! use nnp ; then
-		sed -i 's:PR_SET_NO_NEW_PRIVS:___disable_nnp_hack:' src/sandbox.c || die
-	fi
-
-	# sandbox uses `__asm__ (".symver "...` which does
-	# not play well with gcc's LTO: https://gcc.gnu.org/PR48200
-	filter-lto
-}
-
-multilib_src_configure() {
-	filter-lfs-flags #90228
-
-	ECONF_SOURCE="${S}" econf
-}
-
-multilib_src_test() {
-	# Default sandbox build will run with --jobs set to # cpus.
-	emake check TESTSUITEFLAGS="--jobs=$(makeopts_jobs)"
-}
-
-multilib_src_install_all() {
-	doenvd "${FILESDIR}"/09sandbox
-
-	dodoc AUTHORS ChangeLog* README.md
-}
-
-pkg_postinst() {
-	mkdir -p "${EROOT}"/var/log/sandbox
-	chown root:portage "${EROOT}"/var/log/sandbox
-	chmod 0770 "${EROOT}"/var/log/sandbox
-}
-- 
cgit v1.2.3-65-gdbad