From 4904b314cebe14befad3417f344d22b023f3f4e0 Mon Sep 17 00:00:00 2001
From: Patrice Clement <monsieurp@gentoo.org>
Date: Fri, 3 Nov 2017 23:46:43 +0100
Subject: app-misc/egads: EAPI 6 bump. Package-Manager: Portage-2.3.8,
 Repoman-2.3.3

---
 app-misc/egads/egads-0.9.5-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 app-misc/egads/egads-0.9.5-r1.ebuild

(limited to 'app-misc/egads')

diff --git a/app-misc/egads/egads-0.9.5-r1.ebuild b/app-misc/egads/egads-0.9.5-r1.ebuild
new file mode 100644
index 000000000000..47f7d23b3a5e
--- /dev/null
+++ b/app-misc/egads/egads-0.9.5-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib toolchain-funcs
+
+DESCRIPTION="Entropy Gathering And Distribution System"
+HOMEPAGE="http://www.securesoftware.com/download_egads.htm"
+SRC_URI="http://www.securesoftware.com/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+EGADS_DATADIR=/var/run/egads
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/^BINDIR/d' \
+		-e '/^LIBDIR/d' \
+		-e '/^INCLUDEDIR/d' \
+		"${S}"/Makefile.in || die "Failed to fix Makefile.in"
+	tc-export CC AR RANLIB
+}
+
+src_configure() {
+	econf \
+		--with-egads-datadir="${EGADS_DATADIR}" \
+		--with-bindir=/usr/sbin
+}
+
+src_compile() {
+	emake LIBDIR="/usr/$(get_libdir)"
+}
+
+src_install() {
+	keepdir ${EGADS_DATADIR}
+	fperms +t ${EGADS_DATADIR}
+	# NOT parallel safe, and no DESTDIR support
+	emake -j1 install \
+		BINDIR="${D}"/usr/sbin \
+		LIBDIR="${D}"/usr/$(get_libdir) \
+		INCLUDEDIR="${D}"/usr/include
+
+	dodoc README* doc/*.txt doc/*.html
+}
-- 
cgit v1.2.3-65-gdbad