From 9ef872c7169635b649f7bc89ae9148e798f5f60e Mon Sep 17 00:00:00 2001
From: Miroslav Šulc <fordfrog@gentoo.org>
Date: Tue, 28 Jun 2022 10:23:19 +0200
Subject: media-libs/libnjb: fixed udev reload, eapi8
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/847433
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---
 media-libs/libnjb/libnjb-2.2.7-r1.ebuild | 50 ++++++++++++++++++++++++++++++++
 media-libs/libnjb/libnjb-2.2.7.ebuild    | 10 ++++++-
 2 files changed, 59 insertions(+), 1 deletion(-)
 create mode 100644 media-libs/libnjb/libnjb-2.2.7-r1.ebuild

(limited to 'media-libs/libnjb')

diff --git a/media-libs/libnjb/libnjb-2.2.7-r1.ebuild b/media-libs/libnjb/libnjb-2.2.7-r1.ebuild
new file mode 100644
index 000000000000..2f593d538544
--- /dev/null
+++ b/media-libs/libnjb/libnjb-2.2.7-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool udev
+
+DESCRIPTION="Library for communicating with the Creative Nomad JukeBox digital audio player"
+HOMEPAGE="http://libnjb.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="doc static-libs"
+
+RDEPEND="virtual/libusb:0"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+PATCHES=( "${FILESDIR}"/${P}-exclude-samples.patch )
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+
+	econf \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	udev_newrules "${FILESDIR}"/${PN}.rules 80-${PN}.rules
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/media-libs/libnjb/libnjb-2.2.7.ebuild b/media-libs/libnjb/libnjb-2.2.7.ebuild
index db6b951fbf00..4149c8448297 100644
--- a/media-libs/libnjb/libnjb-2.2.7.ebuild
+++ b/media-libs/libnjb/libnjb-2.2.7.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -40,3 +40,11 @@ src_install() {
 	# package provides .pc files
 	find "${D}" -name '*.la' -delete || die
 }
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3-65-gdbad