blob: 4c02512ae6dd557c162d5a4ddc10fbf04df9c711 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
GNOME2_LA_PUNT="yes"
inherit autotools gnome2
DESCRIPTION="Help browser for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Yelp"
LICENSE="GPL-2+"
SLOT="0"
IUSE=""
KEYWORDS="~alpha amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
RDEPEND="
app-arch/bzip2:=
>=app-arch/xz-utils-4.9:=
dev-db/sqlite:3=
>=dev-libs/glib-2.38:2
>=dev-libs/libxml2-2.6.5:2
>=dev-libs/libxslt-1.1.4
>=gnome-extra/yelp-xsl-3.27.1
>=net-libs/webkit-gtk-2.19.2:4
>=x11-libs/gtk+-3.13.3:3
x11-themes/adwaita-icon-theme
"
DEPEND="${RDEPEND}
dev-libs/appstream-glib
>=dev-util/gtk-doc-am-1.13
dev-util/glib-utils
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
src_prepare() {
# Fix compatibility with Gentoo's sys-apps/man
# https://bugzilla.gnome.org/show_bug.cgi?id=648854
eapply "${FILESDIR}"/${PN}-3.20.0-man-compatibility.patch
eautoreconf
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
--disable-static \
--enable-bz2 \
--enable-lzma \
APPSTREAM_UTIL=""
}
src_install() {
gnome2_src_install
exeinto /usr/libexec/
doexe "${S}"/libyelp/yelp-groff
}
|
GitWeb
