version bump

Package-Manager: portage-2.0.53_rc7

4 files changed, 144 insertions, 2 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index 0cfd3b481737..d505d62c271d 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.128 2005/10/30 16:44:51 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.129 2005/11/02 18:16:13 carlo Exp $
+
+*k3b-0.12.7 (02 Nov 2005)
+
+  02 Nov 2005; Carsten Lohrke <carlo@gentoo.org> +k3b-0.12.7.ebuild:
+  version bump
 
   30 Oct 2005; Carsten Lohrke <carlo@gentoo.org> k3b-0.12.4a.ebuild:
   stable on x86
diff --git a/app-cdr/k3b/Manifest b/app-cdr/k3b/Manifest
index 3dd9753de73d..d5f97532117b 100644
--- a/app-cdr/k3b/Manifest
+++ b/app-cdr/k3b/Manifest
@@ -1,8 +1,9 @@
-MD5 df8c70ef4de4f0faf6b265734e6452ca ChangeLog 18010
+MD5 bde35a2055ff08d141f01944b5ee956a ChangeLog 18122
 MD5 a1b5a05a8513587c957d81f2f7eb44c0 files/digest-k3b-0.11.24 133
 MD5 384b07ebe51023847a4cbdb756c9e867 files/digest-k3b-0.12.4a 135
 MD5 8bdf1530c459d3f1a176f6c1a93ad6ea files/digest-k3b-0.12.5 133
 MD5 fe05540c8069e25ad1a94fb44442f25f files/digest-k3b-0.12.6 133
+MD5 62ef282c26791c31e02912c3c60f3574 files/digest-k3b-0.12.7 133
 MD5 513df86e2c91f7c1209b63cea7d41b84 files/k3b-0.11.17-noarts.patch 893
 MD5 49d32c38a705809a2646228a8d0b71d4 files/k3b-0.12.4a-qt-3.3.5.patch 574
 MD5 5f469d8bb9067596d861b4a9a0a450a1 files/k3b-dvdrip-transcode.patch 1999
@@ -10,4 +11,5 @@ MD5 c3794ba1b13d24f94fe2ab478c92f0ae k3b-0.11.24.ebuild 3106
 MD5 a3567789f9a8771ba54c4b6b7d33c5f2 k3b-0.12.4a.ebuild 3343
 MD5 07519615ce63b52b1fec22f11ce8b6c6 k3b-0.12.5.ebuild 3209
 MD5 29fd37eefbdf691fefa5212bc6d4f3d5 k3b-0.12.6.ebuild 3208
+MD5 5369e74b32bdfe1461c6f5f4b4de118d k3b-0.12.7.ebuild 3208
 MD5 acc03a4b12bb0433a57e95bd253b9501 metadata.xml 156
diff --git a/app-cdr/k3b/files/digest-k3b-0.12.7 b/app-cdr/k3b/files/digest-k3b-0.12.7
new file mode 100644
index 000000000000..e2e5254da6f8
--- /dev/null
+++ b/app-cdr/k3b/files/digest-k3b-0.12.7
@@ -0,0 +1,2 @@
+MD5 fbc9e20f44781da617a67dc6bff74964 k3b-0.12.7.tar.bz2 3772254
+MD5 34d2dc54901436f7da30d5ed1645e079 k3b-i18n-0.12.7.tar.bz2 4268759
diff --git a/app-cdr/k3b/k3b-0.12.7.ebuild b/app-cdr/k3b/k3b-0.12.7.ebuild
new file mode 100644
index 000000000000..6f53516f5a24
--- /dev/null
+++ b/app-cdr/k3b/k3b-0.12.7.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-0.12.7.ebuild,v 1.1 2005/11/02 18:16:13 carlo Exp $
+
+inherit kde eutils
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="css dvdr encode ffmpeg flac hal kde mp3 musepack musicbrainz sndfile vcd vorbis"
+
+DEPEND="kde? ( || ( kde-base/kdesu kde-base/kdebase ) )
+	hal? ( sys-apps/dbus sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( media-libs/musicbrainz )
+	encode? ( media-sound/lame )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( app-cdr/dvd+rw-tools )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+	          media-video/transcode )
+	vcd? ( media-video/vcdimager )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.3
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation for 0.12.5
+LANGS="bg br bs ca cs cy da de el en_GB es et fr ga \
+	hi hu is it lt mk nb nl nn pa pl pt pt_BR ro \
+	ru sl sr sr@Latn sv ta tr uk zh_CN"
+
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+done
+
+pkg_setup() {
+	if use hal && ! built_with_use sys-apps/dbus qt; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt support."
+		die
+	fi
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	local MAKE_LANGS
+	for X in ${LANGS}; do
+		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X}"
+	done
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		sed -i -e "s,^SUBDIRS = .*,SUBDIRS = ${MAKE_LANGS}," Makefile.in
+	fi
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix= \
+			--with-external-libsamplerate	\
+			--without-resmgr		\
+			$(use_with kde k3bsetup)	\
+			$(use_with hal)			\
+			$(use_with encode lame)		\
+			$(use_with ffmpeg)		\
+			$(use_with flac)		\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)		\
+			$(use_with mp3 libmad)		\
+			$(use_with musepack)		\
+			$(use_with musicbrainz)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	local _S=${S}
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		S="${WORKDIR}/${I18N}"
+		cd "${S}"
+		kde_src_compile
+	fi
+	S=${_S}
+}
+
+src_install() {
+	kde_src_install
+
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	local _S=${S}
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		S="${WORKDIR}/${I18N}"
+		cd "${S}"
+		kde_src_install
+	fi
+	S=${_S}
+
+	# Move menu entry
+	if use kde; then
+		mv ${D}/usr/share/applnk/Settings/System/k3bsetup2.desktop ${D}/usr/share/applications/kde/
+	fi
+	rm -fR ${D}/usr/share/applnk/
+}
+
+pkg_postinst() {
+	echo
+	einfo "Make sure you have proper read/write permissions on the cdrom device(s)."
+	einfo "Usually, it is sufficient to be in the cdrom group."
+	echo
+}