1 files changed, 38 insertions, 0 deletions
diff --git a/app-vim/gist/gist-5.1.ebuild b/app-vim/gist/gist-5.1.ebuild
new file mode 100644
index 000000000000..d84280edc82c
--- /dev/null
+++ b/app-vim/gist/gist-5.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-vim/gist/gist-5.1.ebuild,v 1.1 2011/09/19 06:14:45 radhermit Exp $
+
+EAPI=4
+
+inherit vim-plugin
+
+MY_PN="Gist"
+DESCRIPTION="vim plugin: interact with gists (gist.github.com)"
+HOMEPAGE="http://www.vim.org/scripts/script.php?script_id=2423"
+SRC_URI="https://github.com/vim-scripts/${MY_PN}.vim/tarball/${PV} -> ${P}.tar.gz"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="net-misc/curl
+	dev-vcs/git"
+
+VIM_PLUGIN_HELPFILES="${PN}.txt"
+
+src_unpack() {
+	unpack ${A}
+	mv *-${MY_PN}.vim-* "${S}"
+}
+
+src_prepare() {
+	# There's good documentation included with the script, but it's not
+	# in a helpfile. Since there's rather too much information to include
+	# in a VIM_PLUGIN_HELPTEXT, we'll sed ourselves a help doc.
+	mkdir "${S}"/doc
+	sed -e '0,/"=\+$/d' -e '/" GetLatest.\+$/,9999d' -e 's/^" \?//' \
+		-e 's/\(File: \)\([^.]\+\)\.vim/\1*\2.txt*/' \
+		plugin/${PN}.vim \
+		> doc/${PN}.txt
+
+	rm README || die
+}