From c1924147466b05173ab90c554eb87da3cc4f8c9f Mon Sep 17 00:00:00 2001
From: Mike Frysinger <vapier@gentoo.org>
Date: Sun, 17 Jun 2012 21:20:49 +0000
Subject: Version bump.

Package-Manager: portage-2.2.0_alpha110/cvs/Linux x86_64
---
 app-arch/gzip/gzip-1.5.ebuild | 47 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 app-arch/gzip/gzip-1.5.ebuild

(limited to 'app-arch/gzip/gzip-1.5.ebuild')

diff --git a/app-arch/gzip/gzip-1.5.ebuild b/app-arch/gzip/gzip-1.5.ebuild
new file mode 100644
index 000000000000..c36a9cf4194c
--- /dev/null
+++ b/app-arch/gzip/gzip-1.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/gzip/gzip-1.5.ebuild,v 1.1 2012/06/17 21:20:49 vapier Exp $
+
+inherit eutils flag-o-matic unpacker
+
+DESCRIPTION="Standard GNU compressor"
+HOMEPAGE="http://www.gnu.org/software/gzip/"
+SRC_URI="mirror://gnu-alpha/gzip/${P}.tar.xz
+	mirror://gnu/gzip/${P}.tar.xz
+	mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="nls pic static"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpacker
+	cd "${S}"
+	#epatch "${FILESDIR}"/${PN}-1.3.5-rsync.patch
+	epatch "${FILESDIR}"/${PN}-1.3.8-install-symlinks.patch
+}
+
+src_compile() {
+	use static && append-flags -static
+	# avoid text relocation in gzip
+	use pic && export DEFS="NO_ASM"
+	econf || die
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc ChangeLog NEWS README THANKS TODO
+	docinto txt
+	dodoc algorithm.doc gzip.doc
+
+	# keep most things in /usr, just the fun stuff in /
+	dodir /bin
+	mv "${D}"/usr/bin/{gunzip,gzip,uncompress,zcat} "${D}"/bin/ || die
+	sed -e 's:/usr::' -i "${D}"/bin/gunzip || die
+}
-- 
cgit v1.2.3-65-gdbad