# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/go-etcd/go-etcd-0_p20141013.ebuild,v 1.1 2014/10/16 00:13:51 zmedico Exp $

EAPI=5

KEYWORDS="~amd64"
DESCRIPTION="Go client library for etcd"
GO_PN=github.com/coreos/${PN}
HOMEPAGE="https://${GO_PN}"
EGIT_COMMIT="25e2c63be8e8ab405014a78879e0992ae5ff55e8"
SRC_URI="https://${GO_PN}/archive/${EGIT_COMMIT}.zip -> ${P}.zip"
LICENSE="Apache-2.0"
SLOT="0"
IUSE=""
DEPEND=">=dev-lang/go-1.3"
RDEPEND=""
S=${WORKDIR}

src_unpack() {
	default_src_unpack
	mkdir -p src/${GO_PN%/*} || die
	mv ${PN}-${EGIT_COMMIT} src/${GO_PN} || die
}

src_compile() {
	# Create a filtered GOROOT tree out of symlinks,
	# excluding go-etcd, for bug #503324.
	cp -sR /usr/lib/go goroot || die
	rm -rf goroot/src/pkg/${GO_PN} || die
	rm -rf goroot/pkg/linux_${ARCH}/${GO_PN} || die
	GOROOT=${WORKDIR}/goroot GOPATH=${WORKDIR} \
		go install -x ${GO_PN}/etcd || die
}

src_install() {
	insinto /usr/lib/go
	doins -r pkg
	insinto /usr/lib/go/src/pkg
	find src/${GO_PN} -name .gitignore -delete
	doins -r src/*
}