app-cdr/cdrdao/cdrdao-1.1.7-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdrdao/cdrdao-1.1.7-r2.ebuild,v 1.14 2004/06/24 21:31:47 agriffis Exp $

inherit flag-o-matic eutils

DESCRIPTION="Burn CDs in disk-at-once mode -- with optional GUI frontend"
HOMEPAGE="http://cdrdao.sourceforge.net/"
SRC_URI="mirror://sourceforge/cdrdao/${P}.src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc alpha hppa amd64 ia64"
IUSE="gnome oggvorbis perl"

RDEPEND="gnome? ( >=gnome-base/gnome-libs-1.4.1.2-r1
	>=dev-cpp/gnomemm-1.2.2 )
	x86? ( perl? ( oggvorbis? ( dev-perl/libvorbis-perl ) ) )
	dev-perl/MP3-Info
	dev-perl/Audio-Wav
	dev-perl/Audio-Tools
	virtual/cdrtools
	>=sys-apps/sed-4"
DEPEND=">=dev-util/pccts-1.33.24-r1
	${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch ${FILESDIR}/${PF}-mp32dao-gentoo.diff

	if ! use oggvorbis ; then
		cd ${S}/contrib/mp32dao
		sed -i '22s/^/#/' MediaHandler.pm
	fi

	if [ "${ARCH}" = "hppa" ]
	then
		cd ${S}/scsilib/RULES
		for i in parisc parisc64
		do
			cp i386-linux-cc.rul $i-linux-cc.rul
			cp i386-linux-gcc.rul $i-linux-gcc.rul
		done
	fi
}

src_compile() {
	local mygnome=""

	if use gnome ; then
		mygnome=" --with-gnome"
		append-flags $( /usr/bin/gtkmm-config --cflags ) -fno-exceptions
	fi
	# -funroll-loops do not work
	filter-flags "-funroll-loops"

	./configure "${mygnome}" \
		--prefix=/usr \
		--build="${CHOST}"\
		--host="${CHOST}" \
		--with-scglib-inc=/usr/include/scsilib \
		--with-scglib-lib=/usr/lib \
		|| die "configure failed"
	emake || die
}

src_install() {
	# mp32dao.pl
	dobin contrib/mp32dao/mp32dao.pl
	insinto /usr/share/cdrdao/mp32dao
	doins contrib/mp32dao/MediaHandler.pm contrib/mp32dao/mp3handler.pm \
		contrib/mp32dao/BaseInfo.pm
	use oggvorbis && doins contrib/mp32dao/ogghandler.pm

	# cdrdao gets definitely installed
	# binary
	dobin dao/cdrdao

	# data of cdrdao in /usr/share/cdrdao/
	# (right now only driverlist)
	insinto /usr/share/cdrdao
	newins dao/cdrdao.drivers drivers

	# man page
	into /usr
	newman dao/cdrdao.man cdrdao.1

	# documentation
	docinto ""
	dodoc CREDITS INSTALL README* Release*

	# and now the optional GNOME frontend
	if use gnome ; then
		# binary
		into /usr
		dobin xdao/gcdmaster

		# pixmaps for gcdmaster in /usr/share/pixmaps/gcdmaster
		insinto /usr/share/pixmaps/gcdmaster
		doins xdao/*.png xdao/*.xpm

		# application links
		# gcdmaster.desktop in /usr/share/gnome/apps/Applications
		insinto /usr/share/gnome/apps/Applications
		doins xdao/gcdmaster.desktop

		# xcdrdao.1 renamed to gcdmaster.1 in /usr/share/man/man1/
		into /usr
		newman xdao/xcdrdao.man gcdmaster.1
	fi
}