dev-vcs/guilt/guilt-0.32.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/guilt/guilt-0.32.2.ebuild,v 1.1 2010/03/06 14:24:40 ulm Exp $

DESCRIPTION="A series of bash scripts which add a quilt-like interface to git"
HOMEPAGE="http://www.kernel.org/pub/linux/kernel/people/jsipek/guilt/"
# create manpages with "make -C Documentation man"
SRC_URI="mirror://kernel/linux/kernel/people/jsipek/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}-manpages-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="doc"

RDEPEND="dev-util/git"
DEPEND="${RDEPEND}
	doc? ( app-text/asciidoc app-text/xmlto )"

RESTRICT="test"

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e '/^PREFIX/s:=.*:=/usr:' \
		-e "/^htmldir/s:=.*:=/usr/share/doc/${PF}/html:" \
		-e "/^VERSION/s:=.*:=${PV}:" \
		Makefile */Makefile || die
}

src_compile() {
	if use doc ; then
		emake -C Documentation html || die
	fi
}

src_install() {
	emake install DESTDIR="${D}" || die

	dodoc Documentation/{Contributing,Features,HOWTO,Requirements}
	doman Documentation/*.[0-9] || die

	if use doc ; then
		dodir "/usr/share/doc/${PF}/html"
		emake -C Documentation install-html DESTDIR="${D}" || die
	fi
}