media-libs/avidemux-plugins: bump to v2.7.6

Bug: https://bugs.gentoo.org/735568
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

4 files changed, 292 insertions, 0 deletions

diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index 81a3ad8e8a8f..20c2b9ff2f29 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1 +1,2 @@
 DIST avidemux-2.7.4.tar.gz 23815808 BLAKE2B 3a7206f04f568f28dd4d5116c580dd780b057a59e94dd61a2abe5dadfa557291a0c50f917ad1926f9f9a82d01af065c06138f954320e2d9c174fda7583a6b265 SHA512 36d857837cd6a74039a414df16367cd8cbf615173bcc531e57dc0dbfc2e002b1c0c4a80cef73a0d8f25d305deca809af0b5cbcdbad8c311324fa2e64381fd10b
+DIST avidemux-2.7.6.tar.gz 21963753 BLAKE2B 6ca343f90c37844ebfd61123badccefb7327cbf500723c031257cf26500a5b6d98955568c2a9c0d182af68f162e878459a51e6049485937f9b01b4439b32e5e0 SHA512 bc60c733168d40d5b39cc7dd1f74b3f1315e9727302478ef1621e18748bad3400bcfd4d5199862c3093ad9df51385b6b2a96f0f8fedf9bf1c00060327545fb0f
diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.7.6.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.7.6.ebuild
new file mode 100644
index 000000000000..566c3a042992
--- /dev/null
+++ b/media-libs/avidemux-plugins/avidemux-plugins-2.7.6.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Plugins for the video editor media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.7"
+IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio qt5 truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
+	~media-video/avidemux-${PV}:${SLOT}[opengl?,qt5?]
+	dev-lang/spidermonkey:0=
+	dev-libs/libxml2:2
+	media-libs/a52dec
+	media-libs/libass:0=
+	media-libs/libmad
+	media-libs/libmp4v2
+	media-libs/libpng:0=
+	virtual/libiconv
+	aac? (
+		media-libs/faac
+		media-libs/faad2
+	)
+	aften? ( media-libs/aften )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	dcaenc? ( media-sound/dcaenc )
+	dts? ( media-libs/libdca )
+	fdk? ( media-libs/fdk-aac:0= )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	fribidi? ( dev-libs/fribidi )
+	jack? (
+		virtual/jack
+		libsamplerate? ( media-libs/libsamplerate )
+	)
+	lame? ( media-sound/lame )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk ) )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	truetype? ( media-libs/freetype:2 )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	vpx? ( media-libs/libvpx:0= )
+	x264? ( media-libs/x264:0= )
+	x265? ( media-libs/x265:0= )
+	xv? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXv
+	)
+	xvid? ( media-libs/xvid )
+"
+DEPEND="${COMMON_DEPEND}
+	oss? ( virtual/os-headers )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<media-libs/avidemux-plugins-${PV}
+"
+
+S="${WORKDIR}/avidemux2-${PV}"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.6.20-optional-pulse.patch )
+
+src_prepare() {
+	default
+
+	# Don't reapply PATCHES during cmake_src_prepare
+	unset PATCHES
+
+	processes="buildPluginsCommon:avidemux_plugins
+		buildPluginsCLI:avidemux_plugins"
+	use qt5 && processes+=" buildPluginsQt4:avidemux_plugins"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
+	done
+}
+
+src_configure() {
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+
+		local mycmakeargs=(
+			-DAVIDEMUX_SOURCE_DIR='${S}'
+			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
+			-DFAAC="$(usex aac)"
+			-DFAAD="$(usex aac)"
+			-DALSA="$(usex alsa)"
+			-DAFTEN="$(usex aften)"
+			-DDCAENC="$(usex dcaenc)"
+			-DFDK_AAC="$(usex fdk)"
+			-DOPENCORE_AMRWB="$(usex amr)"
+			-DOPENCORE_AMRNB="$(usex amr)"
+			-DLIBDCA="$(usex dts)"
+			-DFONTCONFIG="$(usex fontconfig)"
+			-DJACK="$(usex jack)"
+			-DLAME="$(usex lame)"
+			-DNVENC="$(usex nvenc)"
+			-DOPENGL="$(usex opengl)"
+			-DOPUS="$(usex opus)"
+			-DOSS="$(usex oss)"
+			-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
+			-DQT4=OFF
+			-DFREETYPE2="$(usex truetype)"
+			-DTWOLAME="$(usex twolame)"
+			-DX264="$(usex x264)"
+			-DX265="$(usex x265)"
+			-DXVIDEO="$(usex xv)"
+			-DXVID="$(usex xvid)"
+			-DVDPAU="$(usex vdpau)"
+			-DVORBIS="$(usex vorbis)"
+			-DLIBVORBIS="$(usex vorbis)"
+			-DVPXDEC="$(usex vpx)"
+			-DUSE_EXTERNAL_LIBA52=yes
+			-DUSE_EXTERNAL_LIBASS=yes
+			-DUSE_EXTERNAL_LIBMAD=yes
+			-DUSE_EXTERNAL_LIBMP4V2=yes
+		)
+
+		use qt5 && mycmakeargs+=( -DENABLE_QT5=True )
+		use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_install
+	done
+}
diff --git a/media-video/avidemux/Manifest b/media-video/avidemux/Manifest
index 81a3ad8e8a8f..20c2b9ff2f29 100644
--- a/media-video/avidemux/Manifest
+++ b/media-video/avidemux/Manifest
@@ -1 +1,2 @@
 DIST avidemux-2.7.4.tar.gz 23815808 BLAKE2B 3a7206f04f568f28dd4d5116c580dd780b057a59e94dd61a2abe5dadfa557291a0c50f917ad1926f9f9a82d01af065c06138f954320e2d9c174fda7583a6b265 SHA512 36d857837cd6a74039a414df16367cd8cbf615173bcc531e57dc0dbfc2e002b1c0c4a80cef73a0d8f25d305deca809af0b5cbcdbad8c311324fa2e64381fd10b
+DIST avidemux-2.7.6.tar.gz 21963753 BLAKE2B 6ca343f90c37844ebfd61123badccefb7327cbf500723c031257cf26500a5b6d98955568c2a9c0d182af68f162e878459a51e6049485937f9b01b4439b32e5e0 SHA512 bc60c733168d40d5b39cc7dd1f74b3f1315e9727302478ef1621e18748bad3400bcfd4d5199862c3093ad9df51385b6b2a96f0f8fedf9bf1c00060327545fb0f
diff --git a/media-video/avidemux/avidemux-2.7.6.ebuild b/media-video/avidemux/avidemux-2.7.6.ebuild
new file mode 100644
index 000000000000..ce223b81cf34
--- /dev/null
+++ b/media-video/avidemux/avidemux-2.7.6.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit cmake desktop qmake-utils xdg
+
+DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.7"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug nls nvenc opengl qt5 sdl vaapi vdpau xv"
+
+BDEPEND="qt5? ( dev-qt/linguist-tools:5 )"
+DEPEND="
+	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,xv?,nvenc?]
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+	opengl? ( virtual/opengl:0 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
+	)
+	vaapi? ( x11-libs/libva:0= )
+"
+RDEPEND="${DEPEND}
+	nls? ( virtual/libintl:0 )
+	!<media-video/avidemux-${PV}
+"
+PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt5?]"
+
+S="${WORKDIR}/avidemux2-${PV}"
+
+src_prepare() {
+	eapply "${FILESDIR}"/${P}-qt-5.15.patch
+
+	processes="buildCli:avidemux/cli"
+	use qt5 && processes+=" buildQt4:avidemux/qt4"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
+	done
+
+	if use qt5; then
+		# Fix icon name -> avidemux-2.7
+		sed -i -e "/^Icon/ s:${PN}\.png:${PN}-${SLOT}:" appImage/${PN}.desktop || \
+			die "Icon name fix failed."
+
+		# The desktop file is broken. It uses avidemux3_portable instead of avidemux3_qt5
+		sed -i -re '/^Exec/ s:(avidemux3_)portable:\1qt5:' appImage/${PN}.desktop || \
+			die "Desktop file fix failed."
+
+		# QA warnings: missing trailing ';' and 'Application' is deprecated.
+		sed -i -e 's/Application;AudioVideo/AudioVideo;/g' appImage/${PN}.desktop || \
+			die "Desktop file fix failed."
+
+		# Now rename the desktop file to not collide with 2.6.
+		mv appImage/${PN}.desktop ${PN}-${SLOT}.desktop || die "Collision rename failed."
+	fi
+
+	# Remove "Build Option" dialog because it doesn't reflect
+	# what the GUI can or has been built with. (Bug #463628)
+	sed -i -e '/Build Option/d' avidemux/common/ADM_commonUI/myOwnMenu.h || \
+		die "Couldn't remove \"Build Option\" dialog."
+}
+
+src_configure() {
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	# The build relies on an avidemux-core header that uses 'nullptr'
+	# which is from >=C++11. Let's use the GCC-6 default C++ dialect.
+	append-cxxflags -std=c++14
+
+	local mycmakeargs=(
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLibVA="$(usex vaapi)"
+		-DOPENGL="$(usex opengl)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVIDEO="$(usex xv)"
+	)
+
+	use qt5 && mycmakeargs+=(
+			-DENABLE_QT5="$(usex qt5)"
+			-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+	)
+
+	use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_compile
+	done
+}
+
+src_test() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_test
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_install
+	done
+
+	if use qt5; then
+		cd "${S}" || die "Can't enter source folder"
+		newicon ${PN}_icon.png ${PN}-${SLOT}.png
+		domenu ${PN}-${SLOT}.desktop
+	fi
+}