dev-db/phpmyadmin: Don't depend on dev-lang/php[crypt]

The crypt use flag was removed in dev-lang/php-7.2 and isn't used

Closes: https://bugs.gentoo.org/639396
Package-Manager: Portage-2.3.20, Repoman-2.3.6

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-db/phpmyadmin/phpmyadmin-4.7.7-r1.ebuild b/dev-db/phpmyadmin/phpmyadmin-4.7.7-r1.ebuild
new file mode 100644
index 000000000000..f89f833a9205
--- /dev/null
+++ b/dev-db/phpmyadmin/phpmyadmin-4.7.7-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+inherit eutils webapp
+
+MY_PV=${PV/_/-}
+MY_PN="phpMyAdmin"
+MY_P="${MY_PN}-${MY_PV}-all-languages"
+
+DESCRIPTION="Web-based administration for MySQL database in PHP"
+HOMEPAGE="https://www.phpmyadmin.net/"
+SRC_URI="https://files.phpmyadmin.net/${MY_PN}/${MY_PV}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="setup"
+
+RDEPEND="
+	dev-lang/php[ctype,filter,json,session,unicode]
+	|| (
+		dev-lang/php[mysqli]
+		dev-lang/php[mysql]
+	)
+	virtual/httpd-php:*
+"
+
+need_httpd_cgi
+
+S="${WORKDIR}"/${MY_P}
+
+pkg_setup() {
+	webapp_pkg_setup
+}
+
+src_install() {
+	webapp_src_preinst
+
+	dodoc README RELEASE-DATE-${MY_PV} ChangeLog || die
+	rm -f LICENSE README* RELEASE-DATE-${MY_PV}
+
+	if ! use setup; then
+		rm -rf setup || die "Cannot remove setup utility"
+		elog "The phpMyAdmin setup utility has been removed."
+		elog "It is a regular target of various exploits. If you need it, set USE=setup."
+	else
+		elog "You should consider disabling the setup USE flag"
+		elog "to exclude the setup utility if you don't use it."
+		elog "It regularly is the target of various exploits."
+	fi
+
+	insinto "${MY_HTDOCSDIR#${EPREFIX}}"
+	doins -r .
+
+	webapp_configfile "${MY_HTDOCSDIR#${EPREFIX}}"/libraries/config.default.php
+	webapp_serverowned "${MY_HTDOCSDIR#${EPREFIX}}"/libraries/config.default.php
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en-3.1.txt
+	webapp_src_install
+}