From 54644eabb964676127b8f10c8d6d0fe3977f9777 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Sun, 13 Jun 2021 08:39:22 -0400
Subject: games-emulation/fbzx: add 4.8.0

Trivial bump to get rid of the joystick patch.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 games-emulation/fbzx/Manifest          |  1 +
 games-emulation/fbzx/fbzx-4.8.0.ebuild | 52 ++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 games-emulation/fbzx/fbzx-4.8.0.ebuild

diff --git a/games-emulation/fbzx/Manifest b/games-emulation/fbzx/Manifest
index a26c35938b4f..42b8ab9facc6 100644
--- a/games-emulation/fbzx/Manifest
+++ b/games-emulation/fbzx/Manifest
@@ -1 +1,2 @@
 DIST fbzx_4.6.0.tar.bz2 307308 BLAKE2B 0cf6e9bf3e01c5a03e0925707aab46829ed8e3f0e4c0791d362ab8972d5d0175e35635e5ad6f895db369b4cb543efc40561fa41ec1cfd739c7252762250bdb7e SHA512 4644038c615e2487361e8a7a72d69ae2e136945160d4cc8ed982365243a7e016edff6165ae86a3f50e3f0f4d45540bfd933353ca17596f9d8e10153c492f15d9
+DIST fbzx_4.8.0.tar.bz2 307530 BLAKE2B 465bac143e034604b9f7fb8cf87ef4dcdcec09e7208873350c0c2c63b560c2fc130fa1a665e91156e88563600222a1dc801fcc02c532009f2ebccb5e7946ca14 SHA512 f56a9083a741f98a77e2b9673e569341816cef943973c65c1aa6cb01ad6c2bcd5b663d3db35193196770c3eb046e8a8c15d83c2c122700d2116ad34c5d796cdc
diff --git a/games-emulation/fbzx/fbzx-4.8.0.ebuild b/games-emulation/fbzx/fbzx-4.8.0.ebuild
new file mode 100644
index 000000000000..b69852a2a19c
--- /dev/null
+++ b/games-emulation/fbzx/fbzx-4.8.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Full Screen Sinclair Spectrum emulator"
+HOMEPAGE="http://www.rastersoft.com/programas/fbzx.html"
+SRC_URI="http://www.rastersoft.com/descargas/fbzx/${PN}_${PV}.tar.bz2"
+S="${WORKDIR}/${PN}_${PV}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa pulseaudio"
+
+RDEPEND="
+	media-libs/libsdl2[joystick,video]
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.6.0-makefile.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i "s|/usr/share|${EPREFIX}/usr/share/${PN}|" src/llscreen.cpp || die
+}
+
+src_compile() {
+	tc-export CXX PKG_CONFIG
+
+	emake ALSA=$(usex alsa) PULSE=$(usex pulseaudio)
+}
+
+src_install() {
+	dobin src/${PN}
+	dodoc AMSTRAD CAPABILITIES FAQ HISTORY.md README.{TZX,md} TODO
+	doicon data/${PN}.svg
+	domenu data/${PN}.desktop
+
+	insinto /usr/share/${PN}
+	doins -r data/spectrum-roms
+
+	insinto /usr/share/${PN}/${PN}
+	doins data/keymap.bmp
+}
-- 
cgit v1.2.3-65-gdbad