From 68ae56240c49bb10a7a0109adada6611bfe22471 Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Mon, 13 Sep 2021 21:51:37 +0700
Subject: app-text/coolreader: fix compiling with USE=wxwidgets

Also missing dependencies added
Closes: https://bugs.gentoo.org/811342
Closes: https://bugs.gentoo.org/812245
Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Andrey Grozin <grozin@gentoo.org>
---
 app-text/coolreader/coolreader-3.2.59-r1.ebuild | 71 +++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 app-text/coolreader/coolreader-3.2.59-r1.ebuild

diff --git a/app-text/coolreader/coolreader-3.2.59-r1.ebuild b/app-text/coolreader/coolreader-3.2.59-r1.ebuild
new file mode 100644
index 000000000000..e8422f1bb4a3
--- /dev/null
+++ b/app-text/coolreader/coolreader-3.2.59-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+WX_GTK_VER="3.0-gtk3"
+PLOCALES="bg cs de es hu pl ru uk"
+inherit cmake plocale wxwidgets xdg
+
+CR_PV=$(ver_rs 3 '-')
+SRC_URI="https://github.com/buggins/${PN}/archive/cr${CR_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-cr${CR_PV}"
+
+DESCRIPTION="CoolReader - reader of eBook files (fb2,epub,htm,rtf,txt)"
+HOMEPAGE="https://github.com/buggins/coolreader/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="wxwidgets"
+
+CDEPEND="sys-libs/zlib
+	app-arch/zstd
+	media-libs/libpng:0
+	virtual/jpeg:0
+	media-libs/freetype
+	dev-libs/fribidi
+	media-libs/fontconfig
+	media-libs/harfbuzz
+	dev-libs/libunibreak
+	dev-libs/libutf8proc
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER} )
+	!wxwidgets? ( dev-qt/qtcore:5 dev-qt/qtgui:5 dev-qt/qtwidgets:5 )"
+BDEPEND="${CDEPEND}
+	!wxwidgets? ( dev-qt/linguist-tools:5 )"
+RDEPEND="${CDEPEND}
+	wxwidgets? ( || ( media-fonts/liberation-fonts media-fonts/corefonts ) )"
+
+PATCHES=( "${FILESDIR}"/${PN}-wxwidgets.patch )
+
+src_prepare() {
+	cmake_src_prepare
+	xdg_environment_reset
+
+	# locales
+	plocale_find_changes "${S}"/cr3qt/src/i18n 'cr3_' '.ts'
+	sed -e "s|SET(LANGUAGES .*)|SET(LANGUAGES $(plocale_get_locales))|" \
+		-i "${S}"/cr3qt/CMakeLists.txt \
+		|| die "sed CMakeLists.txt failed"
+}
+
+src_configure() {
+	CMAKE_USE_DIR="${S}"
+	CMAKE_BUILD_TYPE="Release"
+	if use wxwidgets; then
+		setup-wxwidgets
+		local mycmakeargs=(-DGUI=WX)
+	else
+		local mycmakeargs=(-DGUI=QT5)
+	fi
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if ! use wxwidgets; then
+		mv "${D}"/usr/share/doc/cr3/changelog.gz "${D}"/usr/share/doc/${PF}/ || die "mv changelog.gz failed"
+		rmdir "${D}"/usr/share/doc/cr3 || die "rmdir doc/cr3 failed"
+		gunzip "${D}"/usr/share/doc/${PF}/changelog.gz || die "gunzip changelog.gz failed"
+		gunzip "${D}"/usr/share/man/man1/cr3.1.gz || die "gunzip cr3.1.gz failed"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad