From bd894c5ea006c839b7c6a45fe0599e16bc0bbe76 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 22 Feb 2023 20:08:44 +0100
Subject: dev-python/raet: PEP517, py3.11, pypi.eclass
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/raet/raet-0.6.8-r5.ebuild | 47 ++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/raet/raet-0.6.8-r5.ebuild

diff --git a/dev-python/raet/raet-0.6.8-r5.ebuild b/dev-python/raet/raet-0.6.8-r5.ebuild
new file mode 100644
index 000000000000..6736cf75d4d0
--- /dev/null
+++ b/dev-python/raet/raet-0.6.8-r5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Reliable Asynchronous Event Transport Protocol"
+HOMEPAGE="
+	https://github.com/RaetProtocol/raet/
+	https://pypi.org/project/raet/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+	>=dev-python/libnacl-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/ioflo-2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/raet-0.6.8-msgpack-1.0.patch"
+	"${FILESDIR}/raet-0.6.8-py310.patch"
+)
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -e "/setuptools_git/d" -i setup.py || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" raet/test/__init__.py || die "tests failed for ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad