From f426020abb94df394a7b1680ea445f99e2f38d1b Mon Sep 17 00:00:00 2001
From: Zac Medico <zmedico@gentoo.org>
Date: Mon, 7 Jun 2021 00:03:01 -0700
Subject: app-misc/filebus: Bump to version 0.3.0

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Zac Medico <zmedico@gentoo.org>
---
 app-misc/filebus/Manifest             |  1 +
 app-misc/filebus/filebus-0.3.0.ebuild | 67 +++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 app-misc/filebus/filebus-0.3.0.ebuild

(limited to 'app-misc/filebus')

diff --git a/app-misc/filebus/Manifest b/app-misc/filebus/Manifest
index deea6326c413..ba72570b6db6 100644
--- a/app-misc/filebus/Manifest
+++ b/app-misc/filebus/Manifest
@@ -1 +1,2 @@
 DIST filebus-0.2.0.tar.gz 7895 BLAKE2B d113ab7e57ee24371dc9adbeb4767f533007d36cee2a3f55ee7bbcf13c31980355cfee2db748ef6c485bad3cb8c68ba1c31f9829b0c6365fa3b63c4899fb8b02 SHA512 fc7083444a67e36778d15a8af38487024ab661d32b891cfc735fd31cce2ddecfff3ef63c591106d97250373dac9aeef8dd0e8cf0ec260b2d67031018fe66249f
+DIST filebus-0.3.0.tar.gz 16921 BLAKE2B 60ec7eb3fb584c053f00301898b914ba9034e3aaa79a79eecdc31f8e1abd1db5c473486e02761adee537faca6725916cf327e38376bdbbeac2c8548be427089b SHA512 a7dd4cbe96e6e691794ea21b23f79caee518855235c1ee35f857fe2938f437095a9199eb9bf309087cef523b6dfa963f3635d94e9b7ece15bbe1b4284fca793c
diff --git a/app-misc/filebus/filebus-0.3.0.ebuild b/app-misc/filebus/filebus-0.3.0.ebuild
new file mode 100644
index 000000000000..7df930651d17
--- /dev/null
+++ b/app-misc/filebus/filebus-0.3.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+DISTUTILS_OPTIONAL=1
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A user space multicast named pipe implementation backed by a regular file"
+HOMEPAGE="https://github.com/zmedico/filebus"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="+inotify python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RDEPEND="
+	python? (
+		${PYTHON_DEPS}
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		inotify? ( dev-python/watchdog[${PYTHON_USEDEP}] )
+	)"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if use python; then
+		distutils-r1_src_prepare
+	fi
+}
+
+src_compile() {
+	if use python; then
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	"${BASH}" ./lib/bash/filebus-test.bash test || die
+
+	if use python; then
+		distutils-r1_src_test
+	fi
+}
+
+python_test() {
+	python test/test_filebus.py || die "tests failed for ${EPYTHON}"
+}
+
+src_install() {
+	if use python; then
+		distutils-r1_src_install
+	else
+		insinto /usr/libexec/filebus
+		doins lib/bash/*.bash
+		cat <<-EOF > "${T}/filebus"
+		#!/bin/sh
+		exec bash "${EPREFIX}/usr/libexec/filebus/filebus.bash" "\$@"
+		EOF
+		dobin "${T}/filebus"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad