From 1040c69934f53a75ddb782353507a36022d27ae2 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Tue, 19 Apr 2022 10:41:07 -0700
Subject: app-text/gspell: Version bump to 1.10.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 app-text/gspell/Manifest             |  1 +
 app-text/gspell/gspell-1.10.0.ebuild | 61 ++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 app-text/gspell/gspell-1.10.0.ebuild

(limited to 'app-text')

diff --git a/app-text/gspell/Manifest b/app-text/gspell/Manifest
index 34bc9840e69b..e3c76382999b 100644
--- a/app-text/gspell/Manifest
+++ b/app-text/gspell/Manifest
@@ -1 +1,2 @@
+DIST gspell-1.10.0.tar.xz 432484 BLAKE2B aee73d1745720d7c5bef1264ca717866321696953a8c0f2a538e7c8ea2133b8c666b1521280fd6c4f1a9333f178b2559bc21e462f94f7e217480bd3cb5068068 SHA512 8c776f2ea388ab145bc53de112ddc8e737c65ce7be0518edfe695f3e677a89c57a4826eb0fcdc39c5023bd1839ebd60a6a25eb8ac8e3363d0c406994828b743f
 DIST gspell-1.9.1.tar.xz 424252 BLAKE2B 436e6af50f7d1058dd7692c22b5a5e18c25cc76ea6816193e48728f7e1d55ef29af26127403a40d594a2125e4d3e1ee889abe067d2c065de74ae95ca431e5fbe SHA512 72f1fb384e02bb73397b457c3e8a7b98393c9fab5c0dad07f84d1db3f6b75c093663cc83c13fefe868424c503abc2fb89c8b045d0495dd43ddcedad025f23bca
diff --git a/app-text/gspell/gspell-1.10.0.ebuild b/app-text/gspell/gspell-1.10.0.ebuild
new file mode 100644
index 000000000000..4fc667187f18
--- /dev/null
+++ b/app-text/gspell/gspell-1.10.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Spell check library for GTK+ applications"
+HOMEPAGE="https://wiki.gnome.org/Projects/gspell"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # subslot = libgspell-1 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="+introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=app-text/enchant-2.1.3:2
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	dev-libs/icu:=
+	introspection? ( >=dev-libs/gobject-introspection-1.42.0:= )
+"
+DEPEND="${RDEPEND}
+	test? ( sys-apps/dbus )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.6
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		app-text/enchant:2[hunspell]
+		|| (
+			app-dicts/myspell-en[l10n_en(+)]
+			app-dicts/myspell-en[l10n_en-US(+)]
+		)
+	)
+"
+# Tests require a en_US dictionary and fail with deprecated enchant aspell backend:
+# So enchant[hunspell] + myspell-en ensure they pass (hunspell is ordered before aspell),
+# however a different backend like hspell or nuspell + their en_US dict might be fine too,
+# but we don't support them at this time (2020-04-12) in enchant:2
+
+src_prepare() {
+	use vala && vala_setup
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx dbus-run-session emake check
+}
-- 
cgit v1.2.3-65-gdbad