From e171a99080a7b92c70f43396fba36cdb0ee66e45 Mon Sep 17 00:00:00 2001
From: Dennis Lamm <expeditioneer@gentoo.org>
Date: Fri, 23 Jul 2021 06:38:48 +0200
Subject: dev-libs/libcharon: byte-compile missing modules

Bug: https://bugs.gentoo.org/802006
Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>
---
 dev-libs/libcharon/libcharon-4.9.1-r1.ebuild | 72 ++++++++++++++++++++++++++++
 dev-libs/libcharon/metadata.xml              |  3 --
 2 files changed, 72 insertions(+), 3 deletions(-)
 create mode 100644 dev-libs/libcharon/libcharon-4.9.1-r1.ebuild

(limited to 'dev-libs/libcharon')

diff --git a/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild b/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild
new file mode 100644
index 000000000000..8bb7404534a2
--- /dev/null
+++ b/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit cmake python-single-r1
+
+MY_PN="libCharon"
+
+DESCRIPTION="This library facilitates communication between Cura and its backend"
+HOMEPAGE="https://github.com/Ultimaker/libCharon"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+client +dbus test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="
+	${PYTHON_DEPS}
+	dbus? (
+		acct-group/ultimaker
+		acct-user/ultimaker
+		sys-apps/dbus
+	)"
+
+DEPEND="${PYTHON_DEPS}
+	test? (
+		$(python_gen_cond_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	# use current python version, not the latest installed
+	# fix python install location
+	sed -i \
+		-e "s:find_package(Python3 3.4 REQUIRED:find_package(Python3 ${EPYTHON##python} EXACT REQUIRED:g" \
+		-e "s:lib\${LIB_SUFFIX}/python\${Python3_VERSION_MAJOR}\.\${Python3_VERSION_MINOR}/site-packages:$(python_get_sitedir):g" \
+		CMakeLists.txt || die
+
+	sed -i -e "s:/usr/lib/python3/dist-packages/Charon/Service/main.py:$(python_get_sitedir)/Charon/Service/main.py:g" service/charon.service || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_CLIENT=$(usex client ON OFF)
+		-DINSTALL_SERVICE=$(usex dbus ON OFF)
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	if use dbus ; then
+		elog "To start the Charon File Metadata service at boot, add it to the default runlevel with:"
+		elog "    systemctl enable charon"
+	fi
+}
diff --git a/dev-libs/libcharon/metadata.xml b/dev-libs/libcharon/metadata.xml
index f522947e90f4..572a52741db4 100644
--- a/dev-libs/libcharon/metadata.xml
+++ b/dev-libs/libcharon/metadata.xml
@@ -21,9 +21,6 @@
 		<email>perlovka@gmail.com</email>
 		<name>Michael Perlov</name>
 	</maintainer>
-	<slots>
-		<subslots>soname major version number</subslots>
-	</slots>
 	<longdescription>
 		Library to read and write several 3D-printing related file formats including G-Code and Ultimaker File Package (UFP).
 	</longdescription>
-- 
cgit v1.2.3-65-gdbad