From ec7673dd3e92ac60983b62cad60b35003fe3966d Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 18 Feb 2017 11:48:49 +0100
Subject: dev-tex/crosstex: python-single-r1, EAPI=6

---
 dev-tex/crosstex/crosstex-0.6-r1.ebuild | 39 +++++++++++++++++++++++++
 dev-tex/crosstex/crosstex-0.6.ebuild    | 51 ---------------------------------
 2 files changed, 39 insertions(+), 51 deletions(-)
 create mode 100644 dev-tex/crosstex/crosstex-0.6-r1.ebuild
 delete mode 100644 dev-tex/crosstex/crosstex-0.6.ebuild

(limited to 'dev-tex')

diff --git a/dev-tex/crosstex/crosstex-0.6-r1.ebuild b/dev-tex/crosstex/crosstex-0.6-r1.ebuild
new file mode 100644
index 000000000000..75a820ffb6cd
--- /dev/null
+++ b/dev-tex/crosstex/crosstex-0.6-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="CrossTeX - object oriented BibTeX replacement"
+HOMEPAGE="http://www.cs.cornell.edu/people/egs/crosstex/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="dev-python/ply[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	# NB: LIBDIR changed from site-packages to avoid installing .xtx
+	# files to top site-packages dir
+	emake \
+		ROOT="${D}" \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="/lib/crosstex" \
+		install
+
+	python_fix_shebang "${ED%/}/usr/bin"
+	python_optimize "${ED%/}/usr/lib/crosstex"
+
+	dodoc crosstex.pdf
+	if use examples; then
+		docinto examples
+		dodoc -r tests/.
+	fi
+}
diff --git a/dev-tex/crosstex/crosstex-0.6.ebuild b/dev-tex/crosstex/crosstex-0.6.ebuild
deleted file mode 100644
index 5ed8a14e5bd0..000000000000
--- a/dev-tex/crosstex/crosstex-0.6.ebuild
+++ /dev/null
@@ -1,51 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="3"
-PYTHON_DEPEND="2"
-
-inherit multilib python
-
-DESCRIPTION="CrossTeX - object oriented BibTeX replacement"
-HOMEPAGE="http://www.cs.cornell.edu/people/egs/crosstex/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="examples"
-
-RDEPEND="dev-python/ply"
-DEPEND="${RDEPEND}"
-
-pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
-}
-
-src_install() {
-	emake \
-		ROOT="${D}" \
-		PREFIX="/usr" \
-		LIBDIR="/$(get_libdir)/python$(python_get_version)/site-packages" \
-		install || die "emake install failed"
-
-	python_convert_shebangs -r $(python_get_version) "${D}"
-	python_need_rebuild
-
-	insinto /usr/share/doc/${PF}
-	doins "${PN}".pdf
-	if use examples; then
-		insinto /usr/share/doc/${PF}/examples
-		doins tests/*
-	fi
-}
-
-pkg_postinst() {
-	python_mod_optimize ${PN}
-}
-
-pkg_postrm() {
-	python_mod_cleanup ${PN}
-}
-- 
cgit v1.2.3-65-gdbad