From 77996f0bd46af757187d387e251f25fdf21a33f8 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 18 Apr 2019 12:40:20 +0200
Subject: kde-apps: Add KDE Applications 19.04.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11
---
 kde-apps/kwave/Manifest             |  1 +
 kde-apps/kwave/kwave-19.04.0.ebuild | 83 +++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 kde-apps/kwave/kwave-19.04.0.ebuild

(limited to 'kde-apps/kwave')

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 5570f8da4fed..f6d22a3de75c 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1 +1,2 @@
 DIST kwave-18.12.3.tar.xz 6213072 BLAKE2B d460f382bdc8663e7095ca0554d0fc6063f9ab3dcf39ddba3a91f8c59f8acd4fea7f7ccf143e59857917f422ee4276defe8fcfcd54dc5dc1c50f362dd2419e70 SHA512 bffafe6b63cdad5e674a02d9b57e5e658260c2d933ae148e155afc598045a67143f21aad4c52e1437b6f47181b47ee9896e3219700cc8e0aa1c8408fdf797adb
+DIST kwave-19.04.0.tar.xz 6212184 BLAKE2B f2974ae37dac82f328995a62a95fe0ada8aed4dd743dcf7247ac66d756f15a98f597d265415f0f65679fb965490f1929e9cadc68b4927f52e7b7291c4cf10875 SHA512 e77b1505eafcf86c017e77e5fa6b35bb4f254defb1b4c94abff2cb54a42e7aea730c84997118cf717855047a07dc6073f52837e31688ddf0016b3bf7033bda0c
diff --git a/kde-apps/kwave/kwave-19.04.0.ebuild b/kde-apps/kwave/kwave-19.04.0.ebuild
new file mode 100644
index 000000000000..9b6ae0c206e5
--- /dev/null
+++ b/kde-apps/kwave/kwave-19.04.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="http://kwave.sourceforge.net/ https://kde.org/applications/multimedia/kwave/"
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+
+	handbook? ( FDL-1.2 )
+	opus? ( BSD-2 )
+"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| ( media-sound/lame media-sound/toolame media-sound/twolame )
+	)
+	qtmedia? ( $(add_qt_dep qtmultimedia) )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_kdeapps_dep poxml)
+	$(add_qt_dep qtconcurrent)
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	kde5_src_configure
+}
-- 
cgit v1.2.3-65-gdbad