From 65243b01428083dcfcfb8bdbe01480823a55fa27 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 10 Jun 2023 11:56:41 +0200
Subject: kde-frameworks/solid: 5.107.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/solid/solid-5.107.0.ebuild | 50 +++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 kde-frameworks/solid/solid-5.107.0.ebuild

(limited to 'kde-frameworks/solid/solid-5.107.0.ebuild')

diff --git a/kde-frameworks/solid/solid-5.107.0.ebuild b/kde-frameworks/solid/solid-5.107.0.ebuild
new file mode 100644
index 000000000000..efbf369a0e77
--- /dev/null
+++ b/kde-frameworks/solid/solid-5.107.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature
+
+DESCRIPTION="Provider for platform independent hardware discovery, abstraction and management"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="ios"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	sys-apps/util-linux
+	sys-fs/udisks:2
+	virtual/libudev:=
+	ios? (
+		app-pda/libimobiledevice:=
+		app-pda/libplist:=
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+"
+BDEPEND="
+	>=dev-qt/linguist-tools-${QTMIN}:5
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ios IMobileDevice)
+		$(cmake_use_find_package ios PList)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "media player devices support" app-misc/media-player-info
+	fi
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3-65-gdbad