From e4545d6fa63f71463e59794e5119200e68b7573f Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Mon, 13 Feb 2023 11:34:39 +0100
Subject: kde-plasma/libkworkspace: 5.27.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../libkworkspace/libkworkspace-5.27.0.ebuild      | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 kde-plasma/libkworkspace/libkworkspace-5.27.0.ebuild

(limited to 'kde-plasma/libkworkspace/libkworkspace-5.27.0.ebuild')

diff --git a/kde-plasma/libkworkspace/libkworkspace-5.27.0.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.27.0.ebuild
new file mode 100644
index 000000000000..8e90fde047c4
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.27.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.102.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.7
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${RDEPEND}
+	>=kde-plasma/kwin-${PVCUT}:5
+"
+
+S="${S}/${PN}"
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+	rm -rf po/*/docs || die
+	cp -a ../po ./ || die
+
+	eapply "${FILESDIR}/${PN}-5.22.80-standalone.patch"
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" -i CMakeLists.txt || die
+	cat >> CMakeLists.txt <<- _EOF_ || die
+		ki18n_install(po)
+	_EOF_
+
+	ecm_src_prepare
+}
-- 
cgit v1.2.3-65-gdbad