From 6e6adfa40771badfb21c1ff3f71aaf464b754f34 Mon Sep 17 00:00:00 2001
From: Yixun Lan <dlan@gentoo.org>
Date: Tue, 5 Sep 2017 10:36:29 +0800
Subject: net-misc/connman: version bump 1.35

Package-Manager: Portage-2.3.6, Repoman-2.3.3
---
 net-misc/connman/Manifest            |  1 +
 net-misc/connman/connman-1.35.ebuild | 90 ++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 net-misc/connman/connman-1.35.ebuild

(limited to 'net-misc')

diff --git a/net-misc/connman/Manifest b/net-misc/connman/Manifest
index c75b175503b2..f3e4953b89cd 100644
--- a/net-misc/connman/Manifest
+++ b/net-misc/connman/Manifest
@@ -1,3 +1,4 @@
 DIST connman-1.29.tar.xz 653324 SHA256 2a5a69693566f7fd59b2e677fa89356ada6d709998aa665caef8707b1e7a8594 SHA512 19f623dd23c6312f29bbd570dcb22d31154ffcd16ee66ed2280df3d9d844301f18538418363222d99eabdc33da0021488ed66ba2e4f88df30646004b724538ee WHIRLPOOL 9439cadeb20b72c922b1426da213f8567fe7b0da45f9a4abf270c38687a9d9161a8ee14250623344864d612e130e6f28926918468aaf4346a9e5ff41e6ad22bb
 DIST connman-1.33.tar.xz 669800 SHA256 bc8946036fa70124d663136f9f6b6238d897ca482782df907b07a428b09df5a0 SHA512 5670124d2e17ffde4bd5fb878198843b712a31f5840e8523e8247373c8547619e32a4d6dda9cf993eebd5c65bdd256cfc570708a79da1d10f969662b5b750566 WHIRLPOOL eda8176d0d6137b0b94581c9ace23367d7af5722b7d7ea53e173e9466b555f26c9a18a05a07c1533ab11e3197e4303c6c77685a214c3dec2de926d7924f019f2
 DIST connman-1.34.tar.xz 684992 SHA256 a9a0808c729c1f348fc36d8cecb52d19b72bc34cb411c502608cb0e0190fc71e SHA512 732669648936630ae5895cba8bcccc69757ab594bc31ee8e4925b0e402d190939891fac61136f3f086ce708b8d576136f0947914c0cc07427c170cbf9b85a308 WHIRLPOOL bf349ff1f8709e2325d0c316cef922358115c1e9b340b27866d19e03dad98a563f20405ef8290610960b8a33b6de6fbdc717bf958322553fa02da0fba76b3a3a
+DIST connman-1.35.tar.xz 686092 SHA256 66d7deb98371545c6e417239a9b3b3e3201c1529d08eedf40afbc859842cf2aa SHA512 2234b4d18b038f9a33939035cddebd31c74ce962e5616c2c30b2912476612ef3f7d5b9edca64bf6e69fa358252ed432124e036ac3516b291b86695cb9a96c6a8 WHIRLPOOL 6fcb9f78d10cda7e5e143eb5b626c4395671a20b6a00b213757c311702c4386122f08ac3df31fdd13c6137be087b35a9dd213cb360f928725acd7ce3166f6d41
diff --git a/net-misc/connman/connman-1.35.ebuild b/net-misc/connman/connman-1.35.ebuild
new file mode 100644
index 000000000000..12b9cd9901a4
--- /dev/null
+++ b/net-misc/connman/connman-1.35.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+inherit autotools systemd
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://01.org/connman"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+IUSE="${IUSE} bluetooth debug doc examples +ethernet iptables l2tp nftables"
+IUSE="${IUSE} ofono openvpn openconnect pptp policykit tools vpnc +wifi wispr networkmanager"
+
+REQUIRED_USE="|| ( iptables nftables )"
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	iptables? ( >=net-firewall/iptables-1.4.8 )
+	bluetooth? ( net-wireless/bluez )
+	l2tp? ( net-dialup/xl2tpd )
+	nftables? (
+		>=net-libs/libnftnl-1.0.4
+		>=net-libs/libmnl-1.0.0 )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-vpn/openconnect )
+	openvpn? ( net-vpn/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-vpn/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.33-polkit-configure-check-fix.patch"
+	"${FILESDIR}/${PN}-1.33-resolv-conf-overwrite.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--with-systemdunitdir=$(systemd_get_systemunitdir) \
+		--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wispr wispr builtin) \
+		$(use_enable debug) \
+		$(use_enable tools) \
+		$(use_enable networkmanager nmcompat) \
+		--with-firewall=$(usex iptables "iptables" "nftables" ) \
+		--disable-iospm \
+		--disable-iwd \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /usr/lib/${PN}/scripts
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
-- 
cgit v1.2.3-65-gdbad