From 68cbf0ab6e2d940986c6902d72fab3b57e026c21 Mon Sep 17 00:00:00 2001
From: Sébastien Fabbro <bicatali@gentoo.org>
Date: Mon, 29 Feb 2016 22:27:44 +0000
Subject: sci-astronomy/xephem: Version bump

Thanks Ooblick for his work.
Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=572748

Package-Manager: portage-2.2.27
---
 sci-astronomy/xephem/xephem-3.7.7.ebuild | 56 ++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sci-astronomy/xephem/xephem-3.7.7.ebuild

(limited to 'sci-astronomy/xephem/xephem-3.7.7.ebuild')

diff --git a/sci-astronomy/xephem/xephem-3.7.7.ebuild b/sci-astronomy/xephem/xephem-3.7.7.ebuild
new file mode 100644
index 000000000000..967573d37c37
--- /dev/null
+++ b/sci-astronomy/xephem/xephem-3.7.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Interactive tool for astronomical ephemeris and sky simulation"
+HOMEPAGE="http://www.clearskyinstitute.com/xephem"
+SRC_URI="http://97.74.56.125/free/${P}.tar.gz"
+
+LICENSE="XEphem"
+SLOT=0
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND=">=x11-libs/motif-2.3:0
+	virtual/jpeg:0=
+	media-libs/libpng:0="
+DEPEND="${RDEPEND}
+	sys-apps/groff"
+
+PATCHES=(
+	"${FILESDIR}/${P}-respect_env_vars.patch"
+	"${FILESDIR}/${P}-implicits.patch"
+)
+
+src_prepare() {
+	default
+	echo > "${T}"/XEphem "XEphem.ShareDir: /usr/share/${PN}"
+	echo > "${T}"/99xephem "XEHELPURL=/usr/share/doc/${PF}/html/xephem.html"
+}
+
+src_compile() {
+	tc-export CC AR RANLIB
+	emake -C GUI/xephem
+}
+
+src_install() {
+	insinto /usr/share/X11/app-defaults
+	has_version '<x11-base/xorg-x11-7.0' && insinto /etc/X11/app-defaults
+	doins "${T}"/XEphem
+	doenvd "${T}"/99xephem
+	dodoc README
+
+	cd GUI/xephem
+	dobin xephem
+	doman xephem.1
+	newicon XEphem.png ${PN}.png
+	insinto /usr/share/${PN}
+	doins -r auxil catalogs fifos fits gallery lo
+	insinto /usr/share/doc/${PF}/html
+	doins -r help/*
+	make_desktop_entry xephem XEphem ${PN}
+}
-- 
cgit v1.2.3-65-gdbad