From 182814dcb1d2f6e745a6d9715e5f957f8cbe5186 Mon Sep 17 00:00:00 2001
From: Erik Mackdanz <stasibear@gentoo.org>
Date: Sat, 21 Nov 2015 12:30:37 -0600
Subject: sys-fs/lxcfs: New package 0.12

Package-Manager: portage-2.2.24
---
 sys-fs/lxcfs/Manifest                 |  1 +
 sys-fs/lxcfs/files/lxcfs-0.12.initd   | 27 +++++++++++++++++
 sys-fs/lxcfs/files/lxcfs-0.12.service | 13 ++++++++
 sys-fs/lxcfs/lxcfs-0.12.ebuild        | 56 +++++++++++++++++++++++++++++++++++
 sys-fs/lxcfs/metadata.xml             | 21 +++++++++++++
 5 files changed, 118 insertions(+)
 create mode 100644 sys-fs/lxcfs/Manifest
 create mode 100755 sys-fs/lxcfs/files/lxcfs-0.12.initd
 create mode 100644 sys-fs/lxcfs/files/lxcfs-0.12.service
 create mode 100644 sys-fs/lxcfs/lxcfs-0.12.ebuild
 create mode 100644 sys-fs/lxcfs/metadata.xml

(limited to 'sys-fs/lxcfs')

diff --git a/sys-fs/lxcfs/Manifest b/sys-fs/lxcfs/Manifest
new file mode 100644
index 000000000000..561321754033
--- /dev/null
+++ b/sys-fs/lxcfs/Manifest
@@ -0,0 +1 @@
+DIST lxcfs-0.12.tar.gz 34700 SHA256 89fc1caf3787b99dc26dc4b6b35fe216aad09b35c46e4be1d75c0e136f53702c SHA512 0145fe6252990bc14e6db32ab05337df9899c0e4d02ced35a5693da49aa84b4932f3c3bf58422a6d3c12c35a5db73169c4ab79448c928caae61996b0c92b908e WHIRLPOOL 940c9c2dd32547cb1a2a98423e03b3a9b7e8bae00775b45a8bdd7a99ee05ffa9bdf24e863ca65944abef2526d11b6b5532299aabc4ae50c97f42b3c2187ada5b
diff --git a/sys-fs/lxcfs/files/lxcfs-0.12.initd b/sys-fs/lxcfs/files/lxcfs-0.12.initd
new file mode 100755
index 000000000000..a85021401a7d
--- /dev/null
+++ b/sys-fs/lxcfs/files/lxcfs-0.12.initd
@@ -0,0 +1,27 @@
+#!/sbin/runscript
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+DAEMON=/usr/bin/lxcfs
+PIDFILE=/run/lxcfs.pid
+
+start() {
+    ebegin "Starting lxcfs"
+
+    start-stop-daemon --start \
+		      --pidfile ${PIDFILE} \
+		      --exec ${DAEMON} \
+		      --background \
+		      --make-pidfile \
+		      -- \
+		      -f -o allow_other /var/lib/lxcfs
+
+    eend $?
+}
+
+stop() {
+    ebegin "Stopping lxcfs"
+    start-stop-daemon --stop --quiet -R TERM/45 -p ${PIDFILE}
+    eend $?
+}
diff --git a/sys-fs/lxcfs/files/lxcfs-0.12.service b/sys-fs/lxcfs/files/lxcfs-0.12.service
new file mode 100644
index 000000000000..ff737c7e78ce
--- /dev/null
+++ b/sys-fs/lxcfs/files/lxcfs-0.12.service
@@ -0,0 +1,13 @@
+[Unit]
+Description=FUSE filesystem for LXC
+ConditionVirtualization=!container
+Before=lxc.service
+
+[Service]
+ExecStart=/usr/bin/lxcfs -f -o allow_other /var/lib/lxcfs
+KillMode=none
+Restart=on-failure
+ExecStop=/usr/bin/fusermount -u /var/lib/lxcfs
+
+[Install]
+WantedBy=multi-user.target
diff --git a/sys-fs/lxcfs/lxcfs-0.12.ebuild b/sys-fs/lxcfs/lxcfs-0.12.ebuild
new file mode 100644
index 000000000000..24afca093d6c
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-0.12.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils systemd vcs-snapshot
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/lxc/lxcfs.git"
+	EGIT_BRANCH="master"
+	inherit git-r3
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/lxc/lxcfs/archive/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+#IUSE="test"
+
+# Omit all dbus.  Upstream appears to require it because systemd, but
+# lxcfs makes no direct use of dbus.
+RDEPEND="
+	dev-libs/glib:2
+	sys-fs/fuse
+"
+DEPEND="
+	sys-apps/help2man
+	${RDEPEND}
+"
+
+src_prepare() {
+	./bootstrap.sh || die "Failed to bootstrap configure files"
+}
+
+src_configure() {
+	econf --localstatedir=/var
+}
+
+# Test suite fails for me
+# src_test() {
+# 	emake tests
+# 	tests/main.sh || die "Tests failed"
+# }
+
+src_install() {
+	default
+	dodir /var/lib/lxcfs
+	newinitd "${FILESDIR}"/${P}.initd lxcfs
+	systemd_newunit "${FILESDIR}/${P}.service" lxcfs.service
+}
diff --git a/sys-fs/lxcfs/metadata.xml b/sys-fs/lxcfs/metadata.xml
new file mode 100644
index 000000000000..93caf7b90659
--- /dev/null
+++ b/sys-fs/lxcfs/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer status="active">
+		<email>stasibear@gentoo.org</email>
+		<name>Erik Mackdanz</name>
+	</maintainer>
+	<maintainer>
+		<email>john@irc.tm</email>
+		<name>John Cooke</name>
+	</maintainer>
+	<longdescription>
+		LXCFS is a simple userspace filesystem designed to
+		provide a cgroupfs-like tree which is container aware
+		and a set of files which can be bind-mounted over
+		their /proc originals to provide cgroup-aware values.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">lxc/lxfs</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad