dev-python/greenlet/greenlet-0.4.15-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

# Note: greenlet is built-in in pypy
PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} )

inherit distutils-r1 flag-o-matic

DESCRIPTION="Lightweight in-process concurrent programming"
HOMEPAGE="https://pypi.org/project/greenlet/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 -hppa -ia64 ~mips ppc ppc64 s390 ~sparc x86 ~amd64-linux ~x86-linux"
IUSE="doc"

PATCHES=(
	"${FILESDIR}"/${P}-Add-support-for-DEC-Alpha.patch
	"${FILESDIR}"/greenlet-0.4.15-py39.patch
)

DISTUTILS_IN_SOURCE_BUILD=1

distutils_enable_sphinx doc

python_compile() {
	if ! python_is_python3; then
		local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS}
		append-flags -fno-strict-aliasing
	fi

	distutils-r1_python_compile
}

python_test() {
	"${PYTHON}" run-tests.py -n || die "Tests fail with ${EPYTHON}"
}