revbump; correction to deps noted by Arfrever

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 136 insertions, 1 deletions

diff --git a/dev-python/sphinx/ChangeLog b/dev-python/sphinx/ChangeLog
index d2e61ab8cb51..3ffcf65e26a6 100644
--- a/dev-python/sphinx/ChangeLog
+++ b/dev-python/sphinx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/sphinx
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.187 2015/03/28 07:02:05 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.188 2015/04/02 09:56:15 idella4 Exp $
+
+*sphinx-1.3-r1 (02 Apr 2015)
+
+  02 Apr 2015; Ian Delaney <idella4@gentoo.org> +sphinx-1.3-r1.ebuild:
+  revbump; correction to deps noted by Arfrever
 
   28 Mar 2015; Markus Meier <maekke@gentoo.org> sphinx-1.3.ebuild:
   add ~arm, bug #543742
diff --git a/dev-python/sphinx/sphinx-1.3-r1.ebuild b/dev-python/sphinx/sphinx-1.3-r1.ebuild
new file mode 100644
index 000000000000..122a6c6b273b
--- /dev/null
+++ b/dev-python/sphinx/sphinx-1.3-r1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/sphinx-1.3-r1.ebuild,v 1.1 2015/04/02 09:56:15 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1 eutils versionator
+
+MY_PN="Sphinx"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="http://sphinx.pocoo.org/ http://pypi.python.org/pypi/Sphinx"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~x86"
+IUSE="doc latex test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.11[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	=dev-python/alabaster-0.7*[${PYTHON_USEDEP}]
+	=dev-python/sphinx_rtd_theme-0.1*[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		app-text/dvipng
+	)"
+DEPEND="${DEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy) )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib > /dev/null || die
+	"${PYTHON}" -m sphinx.pycode.__init__ \
+		|| die "Grammar generation failed."
+	popd > /dev/null || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc SPHINXBUILD='"${PYTHON}" "${S}/sphinx-build.py"' html
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir"
+	export SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+	cp -r -l tests "${BUILD_DIR}"/ || die
+
+	if $(python_is_python3); then
+		2to3 -w --no-diffs "${BUILD_DIR}"/tests || die
+	fi
+
+	nosetests -w "${BUILD_DIR}"/tests -v \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}
+
+replacing_python_eclass() {
+	local pv
+	for pv in ${REPLACING_VERSIONS}; do
+		if ! version_is_at_least 1.1.3-r4 ${pv}; then
+			return 0
+		fi
+	done
+
+	return 1
+}
+
+pkg_preinst() {
+	if replacing_python_eclass; then
+		# the old python.eclass ebuild will want to remove our pickles...
+		backup_pickle() {
+			# array to enable filename expansion
+			local pickle_name=(
+				"${D}$(python_get_sitedir)"/sphinx/pycode/Grammar*.pickle
+			)
+
+			local dest=${ROOT}${pickle_name[0]#${D}}.backup
+
+			eumask_push 022
+			mkdir -p "${dest%/*}" || die
+			eumask_pop
+
+			cp -p -v "${pickle_name[0]}" "${dest}" \
+				|| die "Unable to backup grammar pickle from overwriting"
+		}
+
+		python_foreach_impl backup_pickle
+	fi
+}
+
+pkg_postinst() {
+	if replacing_python_eclass; then
+		local warned
+
+		restore_pickle() {
+			local backup_name=(
+				"${ROOT}$(python_get_sitedir)"/sphinx/pycode/Grammar*.pickle.backup
+			)
+			local dest=${backup_name[0]%.backup}
+
+			mv -v "${backup_name[0]}" "${dest}" \
+				|| die "Unable to restore grammar pickle backup"
+		}
+
+		python_foreach_impl restore_pickle
+
+		[[ ${warned} ]] && ewarn "Please try rebuilding the package."
+	fi
+}