Stop using base.eclass and deprecated mono.eclass, bump eapi, stop installing static files.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 88 insertions, 2 deletions

diff --git a/media-sound/muine/ChangeLog b/media-sound/muine/ChangeLog
index bb8c5fa6f8d6..916348dc4e58 100644
--- a/media-sound/muine/ChangeLog
+++ b/media-sound/muine/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/muine
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/muine/ChangeLog,v 1.71 2013/10/12 12:13:32 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/muine/ChangeLog,v 1.72 2014/11/21 13:37:10 pacho Exp $
+
+*muine-0.8.11-r3 (21 Nov 2014)
+
+  21 Nov 2014; Pacho Ramos <pacho@gentoo.org> +muine-0.8.11-r3.ebuild:
+  Stop using base.eclass and deprecated mono.eclass, bump eapi, stop installing
+  static files.
 
   12 Oct 2013; Pacho Ramos <pacho@gentoo.org> muine-0.8.11-r2.ebuild:
   Drop unneeded dep
diff --git a/media-sound/muine/muine-0.8.11-r3.ebuild b/media-sound/muine/muine-0.8.11-r3.ebuild
new file mode 100644
index 000000000000..deea95d1c963
--- /dev/null
+++ b/media-sound/muine/muine-0.8.11-r3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/muine/muine-0.8.11-r3.ebuild,v 1.1 2014/11/21 13:37:10 pacho Exp $
+
+EAPI=5
+GCONF_DEBUG="yes"
+
+inherit gnome2 mono-env eutils multilib
+
+DESCRIPTION="A music player for GNOME"
+HOMEPAGE="http://muine.gooeylinux.org/"
+SRC_URI="http://download.gnome.org/sources/muine/0.8/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="flac mad vorbis"
+
+RDEPEND="
+	x11-themes/gnome-icon-theme
+	>=dev-lang/mono-2
+	>=x11-libs/gtk+-2.6:2
+	>=dev-dotnet/gtk-sharp-2.12.9:2
+	>=dev-dotnet/glade-sharp-2.12.6:2
+	>=dev-dotnet/gnome-sharp-2.6:2
+	>=dev-dotnet/gconf-sharp-2.6:2
+	>=dev-dotnet/gnomevfs-sharp-2.6:2
+	>=dev-dotnet/ndesk-dbus-0.4
+	>=dev-dotnet/ndesk-dbus-glib-0.3
+	>=dev-dotnet/taglib-sharp-2.0.3
+	sys-libs/gdbm
+	media-libs/gstreamer:0.10
+	media-libs/gst-plugins-base:0.10
+	media-libs/gst-plugins-good:0.10
+	media-plugins/gst-plugins-gconf:0.10
+	media-plugins/gst-plugins-gnomevfs:0.10
+	flac? ( media-plugins/gst-plugins-flac:0.10 )
+	mad? ( media-plugins/gst-plugins-mad:0.10 )
+	vorbis? (
+		media-plugins/gst-plugins-ogg:0.10
+		media-plugins/gst-plugins-vorbis:0.10
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	app-text/scrollkeeper
+	gnome-base/gnome-common
+	>=dev-util/intltool-0.29
+"
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS PLUGINS README TODO"
+
+	# Fix multimedia key support for >=Gnome-2.22
+	epatch "${FILESDIR}/${P}-multimedia-keys.patch"
+
+	# Replace some deprecated gtk functions
+	epatch "${FILESDIR}/${P}-drop-deprecated.patch"
+
+	# Update icons, upstream bug #623480
+	sed "s:stock_timer:list-add:g" -i src/AddWindow.cs src/StockIcons.cs || die
+	sed "s:stock_music-library:folder-music:g" -i data/glade/PlaylistWindow.glade \
+		src/Actions.cs src/StockIcons.cs || die
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure --disable-static
+}
+
+src_install() {
+	gnome2_src_install
+	insinto /usr/$(get_libdir)/${PN}/plugins
+	doins "${S}"/plugins/TrayIcon.dll
+}